Have MsgBox show other button than Yes No Cancel

[szakharov7723]

So currently my code has vbQuestion & vbYesNoCancel. I am trying to figure out if I can replace Yes No Cancel with my own options. Preferably (not necessarily) without editing code too much.

    If Dir(FPath & "\" & FName & FExt) <> "" Then
        wAns = MsgBox("The file already exists. Do You want to replace it", vbQuestion & vbYesNoCancel, "Save Copy")
        Select Case wAns
            Case vbYes
                Application.DisplayAlerts = False
                ThisWorkbook.Save
                Application.DisplayAlerts = True
            Case vbNo
                Application.DisplayAlerts = False
                ThisWorkbook.SaveAs Filename:=FPath & FName & "_2" & FExt
                Application.DisplayAlerts = True
            Case vbCancel
                MsgBox "Process canceled"
        End Select

 

[LuisV805]

The only way to have customized buttons is to create a form. Here's one way to make it work with minimal changes...

[FONT=Verdana]  Application.DisplayAlerts = False[/FONT]
[FONT=Verdana]  If Dir(FPath & "" & FName & FExt) <> "" Then[/FONT]

[FONT=Verdana]    If MsgBox("The file already exists. Do You want to replace it", vbYesNo) = vbYes Then[/FONT]
[FONT=Verdana]      ThisWorkbook.Save[/FONT]
[FONT=Verdana]    ElseIf MsgBox("Would you like to save a copy?", vbYesNo) = vbYes Then[/FONT]
[FONT=Verdana]      ThisWorkbook.SaveAs FileName:=FPath & "" & FName & "_2" & FExt[/FONT]
[FONT=Verdana]    Else[/FONT]
[FONT=Verdana]      MsgBox ("Process canceled")[/FONT]
[FONT=Verdana]    End If
[/FONT]
[FONT=Verdana]  End If[/FONT]
[FONT=Verdana]  Application.DisplayAlerts = True[/FONT]

 

[Fluff]

Whilst it's possible to customise the buttons, it's not that easy.
You would be better off creating a userform instead.

 

[szakharov7723]

It is something I have never done before.well.. Only did it few times in Access very long time ago.
I will try to research on it.
So if I create this userform, will I still keep my code ?

 

[CalcSux78]

@szakharov7723
Here's a site that might help with the basics of userforms: https://excelmacromastery.com/vba-user-forms-2/

 

[Fluff]

You could use your code like

   If Dir(fPath & "\" & Fname & FExt) <> "" Then
      UserForm3.Show
      Select Case UserForm3.Tag
         Case 1
            Application.DisplayAlerts = False
            ThisWorkbook.Save
            Application.DisplayAlerts = True
         Case 2
            Application.DisplayAlerts = False
            ThisWorkbook.SaveAs FileName:=fPath & Fname & "_2" & FExt
            Application.DisplayAlerts = True
         Case 3
            MsgBox "Process canceled"
      End Select
      Unload UserForm3
   End If

And on the userform, you would need code like

Private Sub CommandButton1_Click()
Me.Tag = 1
Me.Hide
End Sub

Private Sub CommandButton2_Click()
Me.Tag = 2
Me.Hide
End Sub

Private Sub CommandButton3_Click()
Me.Tag = 3
Me.Hide
End Sub

It may just be simpler to accept the limitations of the standard Msgbox