Have Listbox show dd/mm/yyy

[ipbr21054]

I am using the code below
When i search my worksheet the list box doesnt match the date

Please advise how i have it show dd/mm/yyyy

Private Sub TextBox1_Change()
  TextBox1 = UCase(TextBox1)
  Dim r As Range, f As Range, cell As String, added As Boolean
  Dim sh As Worksheet
  
  Set sh = Sheets("KDX2LIST")
  sh.Select
  With ListBox1
    .Clear
    .ColumnCount = 7
    .ColumnWidths = "160;230;90;110;180;100"

    If TextBox1.Value = "" Then Exit Sub
    Set r = Range("B4", Range("B" & Rows.Count).End(xlUp))
    Set f = r.Find(TextBox1.Value, LookIn:=xlValues, LookAt:=xlPart)
    If Not f Is Nothing Then
      cell = f.Address
      Do
        added = False
        For i = 0 To .ListCount - 1
          Select Case StrComp(.List(i), f.Value, vbTextCompare)
            Case 0, 1
              .AddItem f.Value, i
              .List(i, 6) = f.Row                'ROW NUMBER
              .List(i, 1) = f.Offset(, -1).Value 'CUSTOMER
              .List(i, 2) = f.Offset(, 2).Value  'YEAR
              .List(i, 3) = f.Offset(, 3).Value  'DATE
              .List(i, 4) = f.Offset(, 4).Value  'VIN
              .List(i, 5) = f.Offset(, 5).Value  'TOOL USED

              added = True
              Exit For
          End Select
        Next
        If added = False Then
          .AddItem f.Value
              .List(.ListCount - 1, 6) = f.Row                'ROW NUMBER
              .List(.ListCount - 1, 1) = f.Offset(, -1).Value 'CUSTOMER
              .List(.ListCount - 1, 2) = f.Offset(, 2).Value  'YEAR
              .List(.ListCount - 1, 3) = f.Offset(, 3).Value  'DATE
              .List(.ListCount - 1, 4) = f.Offset(, 4).Value  'VIN
              .List(.ListCount - 1, 5) = f.Offset(, 5).Value  'TOOL USED

        End If
        Set f = r.FindNext(f)
      Loop While Not f Is Nothing And f.Address <> cell
      TextBox1Search = UCase(TextBox1Search)
      .TopIndex = 0
      Else
      MsgBox "NO INFO WAS FOUND", vbCritical, "KDX2 SEARCH VEHICLE"
      TextBox1.Value = ""
      TextBox1.SetFocus
    End If
  End With
End Sub

 

[dmt32]

Try using the Range.TEXT property - this should return what you see in the cell rather than its underlying value

Private Sub TextBox1_Change()
  TextBox1 = UCase(TextBox1)
  Dim r As Range, f As Range, cell As String, added As Boolean
  Dim sh As Worksheet
  
  Set sh = Sheets("KDX2LIST")
  sh.Select
  With ListBox1
    .Clear
    .ColumnCount = 7
    .ColumnWidths = "160;230;90;110;180;100"

    If TextBox1.Value = "" Then Exit Sub
    Set r = Range("B4", Range("B" & Rows.Count).End(xlUp))
    Set f = r.Find(TextBox1.Value, LookIn:=xlValues, LookAt:=xlPart)
    If Not f Is Nothing Then
      cell = f.Address
      Do
        added = False
        For i = 0 To .ListCount - 1
          Select Case StrComp(.List(i), f.Value, vbTextCompare)
            Case 0, 1
              .AddItem f.Value, i
              .List(i, 6) = f.Row                'ROW NUMBER
              .List(i, 1) = f.Offset(, -1).Value 'CUSTOMER
              .List(i, 2) = f.Offset(, 2).Value  'YEAR
              .List(i, 3) = f.Offset(, 3).Text  'DATE
              .List(i, 4) = f.Offset(, 4).Value  'VIN
              .List(i, 5) = f.Offset(, 5).Value  'TOOL USED

              added = True
              Exit For
          End Select
        Next
        If added = False Then
          .AddItem f.Value
              .List(.ListCount - 1, 6) = f.Row                'ROW NUMBER
              .List(.ListCount - 1, 1) = f.Offset(, -1).Value 'CUSTOMER
              .List(.ListCount - 1, 2) = f.Offset(, 2).Value  'YEAR
              .List(.ListCount - 1, 3) = f.Offset(, 3).Text  'DATE
              .List(.ListCount - 1, 4) = f.Offset(, 4).Value  'VIN
              .List(.ListCount - 1, 5) = f.Offset(, 5).Value  'TOOL USED

        End If
        Set f = r.FindNext(f)
      Loop While Not f Is Nothing And f.Address <> cell
      TextBox1Search = UCase(TextBox1Search)
      .TopIndex = 0
      Else
      MsgBox "NO INFO WAS FOUND", vbCritical, "KDX2 SEARCH VEHICLE"
      TextBox1.Value = ""
      TextBox1.SetFocus
    End If
  End With
End Sub

Dave

 

[ipbr21054]

Thanks very much