Handling errors from a WinHttpReq function

[most]

Hi,
I would like some assistance with handling errors from this function.
SomeDownload1 will return WinHttpReq.Status = 404, what is the best practice of returning a error code back to sub routine?
SomeDownload2 will run-time error at line 6 (WinHttpReq.send), how to handle this?

I searched but could not find any match on my particular case.

Function Download(myURL As String, LocalFilePath As String)
  Dim WinHttpReq As Object
  Dim oStream As Object
  Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
  WinHttpReq.Open "GET", myURL, False, "", "" '("username", "password")
  WinHttpReq.send

   If WinHttpReq.Status = 200 Then
      Set oStream = CreateObject("ADODB.Stream")
      oStream.Open
      oStream.Type = 1
      oStream.Write WinHttpReq.responseBody
      oStream.SaveToFile LocalFilePath, 2  '1=no overwrite, 2=overwrite
      oStream.Close
   End If

End Function
Sub SomeDownload1()
  Dim dl_URL As String
  Dim dl_FilePath As String
   dl_URL = "https://www.exist.com/doesnotexist.xlam"
   dl_FilePath = Application.UserLibraryPath & "\Test1.xlam"
  Call Download(dl_URL, dl_FilePath)
End Sub
Sub SomeDownload2()
  Dim dl_URL As String
  Dim dl_FilePath As String
   dl_URL = "https://www.doesnotexist.com/Whatever.xlam"
   dl_FilePath = Application.UserLibraryPath & "\Test2.xlam"
  Call Download(dl_URL, dl_FilePath)
End Sub

 

[Domenic]

You can amend your Download function so that it returns True when successful, and False when it's unsuccessful. It can also be amended to return the error message to the calling procedure. Maybe something like this...

Option Explicit

Sub test()

    Dim ErrorMessage As String
    Dim IsDownloadSuccessful As Boolean
    
    IsDownloadSuccessful = Download("http://xl-central.com/", "c:\users\domenic\desktop\sample.txt", ErrorMessage)
    
    If Not IsDownloadSuccessful Then
        MsgBox ErrorMessage, vbExclamation, "Error"
        Exit Sub
    End If
    
    'etc
    '
    '
    
End Sub

Function Download(myURL As String, LocalFilePath As String, ErrorMessage As String) As Boolean
    Dim WinHttpReq As Object
    Dim oStream As Object
    
    Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
    WinHttpReq.Open "GET", myURL, False, "", "" '("username", "password")
    WinHttpReq.Send
    
    With WinHttpReq
        If .Status <> 200 Then
            ErrorMessage = "Error " & .Status & ": " & .StatusText
            Download = False
            Exit Function
        End If
    End With

    Set oStream = CreateObject("ADODB.Stream")
    oStream.Open
    oStream.Type = 1
    oStream.Write WinHttpReq.ResponseBody
    oStream.SaveToFile LocalFilePath, 2  '1=no overwrite, 2=overwrite
    oStream.Close
    
    Download = True
End Function

Hope this helps!

 

[most]

Your solution was really nice, but it stills ends with runtime error, i.e. if url would be "http://xl-entral.com/" (misspelled).
I just came up with this solution, not as nice as yours but it seems to work with my test cases.
I will investigate how I can combine best parts of our codes. Thanks!

Function Download2(myURL As String, LocalFilePath As String)
  Dim WinHttpReq As Object
  Dim oStream As Object
  Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
  WinHttpReq.Open "GET", myURL, False, "", "" '("username", "password")
On Error Resume Next
  WinHttpReq.Send
On Error GoTo 0

   If WinHttpReq.Status = 200 Then
      Set oStream = CreateObject("ADODB.Stream")
      oStream.Open
      oStream.Type = 1
      oStream.Write WinHttpReq.ResponseBody
      oStream.SaveToFile LocalFilePath, 2  '1=no overwrite, 2=overwrite
      oStream.Close
     Else
      Download = WinHttpReq.Status
   End If

End Function
Sub SomeDownload1()
  Dim dl_URL As String
  Dim dl_FilePath As String
   dl_URL = "https://www.exist.com/doesnotexist.xlam"
   dl_FilePath = Application.UserLibraryPath & "\Test1.xlam"

  If Download(dl_URL, dl_FilePath) <> 0 Then
    Debug.Print "Error download"
   Else
    Call Download(dl_URL, dl_FilePath)
  End If

End Sub
Sub SomeDownload2()
  Dim dl_URL As String
  Dim dl_FilePath As String
   dl_URL = "https://www.doesnotexist.com/Whatever.xlam"
   dl_FilePath = Application.UserLibraryPath & "\Test2.xlam"
     
  If Download(dl_URL, dl_FilePath) <> 0 Then
    Debug.Print "Error download"
   Else
    Call Download(dl_URL, dl_FilePath)
  End If
 
End Sub

 

[Domenic]

In that case, how about amending it as follows...

Function Download(myURL As String, LocalFilePath As String, ErrorMessage As String) As Boolean
    Dim WinHttpReq As Object
    Dim oStream As Object
    
    On Error GoTo ErrHandler
    
    Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
    WinHttpReq.Open "GET", myURL, False, "", "" '("username", "password")
    WinHttpReq.Send
    
    If WinHttpReq.Status = 200 Then
        Set oStream = CreateObject("ADODB.Stream")
        oStream.Open
        oStream.Type = 1
        oStream.Write WinHttpReq.ResponseBody
        oStream.SaveToFile LocalFilePath, 2  '1=no overwrite, 2=overwrite
        oStream.Close
        Download = True
        Exit Function
    End If
    
    With WinHttpReq
        ErrorMessage = "Error " & .Status & ": " & .StatusText
        Download = False
        Exit Function
    End With
    
ErrHandler:
    ErrorMessage = "Error " & Err.Number & ": " & Err.Description
    Download = False
    
End Function