group of objects saved as png

[smak]

I have objects that I have grouped. I want to save these grouped items as a png so it can be used later. .

I also pasted a copy of what the image would look partially like when it is saved.

when I have gotten charts to do this properly I used the code:

    ActiveSheet.ChartObjects("Chart 2").Activate
    ActiveChart.Export "O:\OPHS\DE\Stephanie\c19 report\temp saved documents\images of charts\Cumulative Line Charts.png"

my grouped objects are referenced in the code below

    ActiveSheet.Shapes.Range(Array("map")).Select

 

[John_w]

Basically the same as your charts code - copy the grouped shape to a temporary chart and save that.

Public Sub Save_Shapes_Group_As_Image()

    Dim shp As Shape
    
    Set shp = ActiveSheet.Shapes("map")    
    Save_Object_As_Picture shp, ThisWorkbook.Path & "\map.png", "png"
    
End Sub


Private Sub Save_Object_As_Picture(saveObject As Object, imageFileName As String, imageType As String)

    'Save a picture of an object as a JPEG/PNG/GIF/SVG file
    
    'Arguments
    'saveObject     - any object in the CopyPicture method's 'Applies To' list, for example a Range or Shape
    'imageFileName  - the .jpg/.jpeg/.png/.gif/.svg file name (including folder path if required) the picture will be saved as
    'imageType      - the image type: jpeg, png, gif or svg
    
    Dim temporaryChart As ChartObject
     
    Application.ScreenUpdating = False
    
    saveObject.CopyPicture xlScreen, xlPicture
    
    Set temporaryChart = ActiveSheet.ChartObjects.Add(0, 0, saveObject.Width, saveObject.Height)
    With temporaryChart
        .Activate                               'Required, otherwise image is blank
        .Border.LineStyle = xlLineStyleNone     'No border
        .Chart.Paste
        .Chart.Export imageFileName, imageType
        .Delete
    End With
    
    Application.ScreenUpdating = True
    
    Set temporaryChart = Nothing
    
End Sub