getting rid of multiple entries of the same name but adding a value together

[Ivn68]

in columnA I have a name and in columnB I have a value
there would be multiple entries for the same name but different values in columnB
i need to get rid of the duplicate entry but the values in columnB to be added together

thinkng im gonna need to run a loop in vba

 

[Niteshnitesh]

Concatenate column a and b then highlight duplicates and then filter duplicates and delete them.

 

[hiker95]

Ivn68,

So that we can get it right on the first try, can we see your actual raw data workbook/worksheet, and, can we see what the results (manually formatted by you) should look like?

You can post your workbook/worksheets to the following free site (sensitive data changed), mark the workbook for sharing, and, provide us with a link to your workbook:

https://dropbox.com

 

[Fluff]

How about

Sub Totalunique()

   Dim cl As Range
   
   With CreateObject("scripting.dictionary")
      For Each cl In Range("A2", Range("A" & Rows.Count).End(xlUp))
         If Not .exists(cl.Value) Then
            .Add cl.Value, cl.Offset(, 1).Value
         Else
            .Item(cl.Value) = .Item(cl.Value) + cl.Offset(, 1).Value
         End If
      Next cl
      Range("A1").CurrentRegion.Offset(1).ClearContents
      Range("A2").Resize(.Count).Value = Application.Transpose(.keys)
      Range("B2").Resize(.Count).Value = Application.Transpose(.items)
   End With
End Sub

 

[Ivn68]

in columnA it only added 2 entries at a time
so if i have the same name 4 times i end up with 2 entries i only want one

 

[Fluff]

How about

Sub Totalunique()

   Dim cl As Range
   
   With CreateObject("scripting.dictionary")
     [COLOR=#ff0000] .CompareMode = vbTextCompare[/COLOR]
      For Each cl In Range("A2", Range("A" & Rows.Count).End(xlUp))
         If Not .exists(cl.Value) Then
            .Add cl.Value, cl.Offset(, 1).Value
         Else
            .Item(cl.Value) = .Item(cl.Value) + cl.Offset(, 1).Value
         End If
      Next cl
      Range("A1").CurrentRegion.Offset(1).ClearContents
      Range("A2").Resize(.Count).Value = Application.Transpose(.keys)
      Range("B2").Resize(.Count).Value = Application.Transpose(.items)
   End With
End Sub

 

[Ivn68]

sorry i got it to work i just didn't read the results wrong thanks a lot

 

[Fluff]

Glad to help & thanks for the feedback

 

[Ivn68]

How would the vba change if I need to ad column C together and not column B

 

[Fluff]

Like this

   For Each Cl In Range("A2", Range("A" & Rows.Count).End(xlUp))
     If Not .exists(Cl.Value) Then
        .Add Cl.Value, Cl.Offset(, [COLOR=#ff0000]2[/COLOR]).Value
     Else
        .Item(Cl.Value) = .Item(Cl.Value) + Cl.Offset(, [COLOR=#ff0000]2[/COLOR]).Value
     End If
   Next Cl