Getting information from steam market

[Ramballah]

Hello,

I am trying to make an excel spreadsheet that imports data from the steam marketplace so that I can keep track of prices of certain items.
I have found that google spreadsheets allows this very easily but I'd very rather use excel as I use it way more than google spreadsheets.
So basically what I want is to open my excel spreadsheet and it will automatically update the prices for me.
My spreadsheet would look something like this:

I dont know much about VBA my self so I don't know if this is doable.
The website link for this specific item is: click here
(if this turns out to be something thats to be done with VBA, I maybe should mention that I would like this for multiple items and not only 1)
EDIT* using web queries etc doesn't work for steam market
Thanks in advance,
Ram

 

[Ramballah]

Hello, I have found some things that could potentially help with this on the internet. However I have some issues that I cannot seem to solve my self.
People seem to be using the webservice function to get data from the website. However when I use webservice I get a #value error saying that my organizations administrator turned off the service required for this function. I am the administrator but I can't find anywhere online how to enable the service required. But when I use webservice("google.com") it works and returns a lot of information to me. Then the next issue I have (if the #value error will be fixed). is how do I extract the right data from that string of text I get?

I hope this makes the problem easier to solve...

 

[Ramballah]

New update, i somehow managed to change the link to something that excel can return.
changed the link to : https://steamcommunity.com/market/p...id=252490&market_hash_name=Neon Tools Storage
Now excel returns me with:

{"success":true,"lowest_price":"7,74€","volume":"28","median_price":"7,57€"}

How do I subscract the "7,74" from this? I somehow fail to do that even with the help of google.

 

[Domenic]

First, set a reference (Visual Basic Editor > Tools > References) to Microsoft XML, v6.0. Then try the following macro..

Option Explicit

Sub test()

    'Set a reference (Visual Basic Editor > Tools > References) to Microsoft XML, v6.0

    Dim xmlReq As MSXML2.ServerXMLHTTP60
    Dim strURL As String
    Dim strResp As String
    Dim strLowestPrice As String
    
    strURL = "https://steamcommunity.com/market/priceoverview/?currency=3&appid=252490&market_hash_name=Neon%20Tools%20Storage"
    
    Set xmlReq = New MSXML2.ServerXMLHTTP60
    
    With xmlReq
        .Open "GET", strURL, False
        .send
        If .Status <> 200 Then
            MsgBox "Error " & .Status & ":  " & .statusText
            Exit Sub
        End If
        strResp = .responseText
    End With
    
    strLowestPrice = Mid$(strResp, InStr(1, Replace(strResp, ":", "^", 1, 1), ":") + 2)
    strLowestPrice = Left$(strLowestPrice, InStr(1, strLowestPrice, """") - 2)
    strLowestPrice = Trim$(strLowestPrice)
    
    MsgBox "Lowest price:  " & strLowestPrice
    
    Set xmlReq = Nothing

End Sub

Hope this helps!