Getting excel pie chart slices to use the colours from my data series

[Big Maceo]

Hi, I'm producing a pie chart in excel (2016), and each line in the data series is colour coded. I'm trying (unsuccessfully) to get excel to use the colours for each line in the data series for the corresponding pie slice in the chart, but it just uses its own default colours.

Can anybody tell me how to do it?

 

[Jon Peltier]

I wrote a tutorial about this on my blog a while back, Color Plotted Points to Match Cells.

Short answer, try this procedure, which works for pie chart, but also donut charts, column charts, and bar charts.

Sub ColorPointsToMatchCells()
  Dim srs As Series
  Dim sFmla As String
  Dim vFmla As Variant
  Dim sYvals As String
  Dim rYvals As Range
  Dim iPt As Long
  Dim nPts As Long

  If ActiveChart Is Nothing Then GoTo OuttaHere

  For Each srs In ActiveChart.SeriesCollection
    Select Case srs.ChartType
      ' only do pie, bar, column charts
      Case xlPie, xlDoughnut, xlBarClustered, xlBarStacked, xlBarStacked100, _
          xlColumnClustered, xlColumnStacked, xlColumnStacked100

        On Error GoTo SeriesError

        ' get series information
        sFmla = srs.Formula
        nPts = srs.Points.Count
        vFmla = Split(sFmla, ",")
        sYvals = vFmla(LBound(vFmla) + 2)
        Set rYvals = Range(sYvals)

        For iPt = 1 To nPts
          ' don't change point color if cell has no fill color
          If rYvals.Cells(iPt).Interior.Pattern = xlSolid Then
            srs.Points(iPt).Interior.Color = rYvals.Cells(iPt).Interior.Color
          End If
        Next
    End Select

SeriesError:
    On Error Resume Next
  Next

OuttaHere:

End Sub

 

[Big Maceo]

Thanks very much for this. Much appreciated.