Getting difference between two cell based on the above cell value and below cell value

[knoll126]

BehEvent <tbody> </tbody>	Time <tbody> </tbody>
Lobtailing	21:11.2 <tbody> </tbody>
Blow	21:33.6 <tbody> </tbody>
Blow	22:21.7 <tbody> </tbody>
Blow	22:36.3 <tbody> </tbody>
Lobtailing	23:26.5 <tbody> </tbody>
Lobtailing	23:30.6 <tbody> </tbody>
Blow	24:07.6 <tbody> </tbody>
Blow	24:29.8 <tbody> </tbody>
Fluke Up Dive	24:50.9 <tbody> </tbody>

<tbody>
</tbody>

I would like help trying to create a formula to subtract the difference in time between the first blow and the last blow of the same sequence. So between Lobtailing and Lobtailing and between Lobtailing and Fluke Up Dive. So getting the difference between 21:33.6 - 22:36.3 and 24:07.6 - 24:29.8. Any ideas?

Thanks.

 

[Gerald Higgins]

Hi, you can probably do this with one or two helper columns, if that's an option for you. Is it ?

 

[knoll126]

What is a helper column?

 

[jtakw]

Hi,

Don't know how you might want your layout to look like, but here's one way, shown with or without the words "Time interval is:", which you can change to say anything you want.

Excel 2010
	A	B	C
1	BehEvent	Time
2	Lobtailing	21:11.2
3	Blow	21:33.6	21:33.6
4	Blow	22:21.7
5	Blow	22:36.3	Time interval is: 01.02.7
6	Lobtailing	23:26.5
7	Lobtailing	23:30.6
8	Blow	24:07.6	24:07.6
9	Blow	24:29.8	Time interval is: 00.22.2
10	Fluke Up Dive	24:50.9
Sheet1

Cell Formulas
Range	Formula
C2	=IF(AND(A2="Blow",OR(A1={"Lobtailing","Fluke Up Dive"})),B2,IF(AND(A2="Blow",OR(A3={"Lobtailing","Fluke Up Dive"})),"Time interval is: "&TEXT(B2-LOOKUP(9.99999999999999E+307,C1:C$2),"mm.ss.0"),""))

Excel 2010
	A	B	C
1	BehEvent	Time
2	Lobtailing	21:11.2
3	Blow	21:33.6	21:33.6
4	Blow	22:21.7
5	Blow	22:36.3	01:02.7
6	Lobtailing	23:26.5
7	Lobtailing	23:30.6
8	Blow	24:07.6	24:07.6
9	Blow	24:29.8	00:22.2
10	Fluke Up Dive	24:50.9
Sheet2

Cell Formulas
Range	Formula
C2	=IF(AND(A2="Blow",OR(A1={"Lobtailing","Fluke Up Dive"})),B2,IF(AND(A2="Blow",OR(A3={"Lobtailing","Fluke Up Dive"})),B2-LOOKUP(9.99999999999999E+307,C1:C$2),""))

C2 formula copied down.

 

[Gerald Higgins]

And here's a solution using a helper column (in column C).

I'm assuming all cell references are the same as in post #4 .

The helper column can be hidden if required.

In C2
=IF(AND(A2="Blow",A1<>"Blow"),B2,IF(AND(A2="Blow",A1="Blow"),C1,0))

In D2
=IF(AND(A2="Blow",A3<>"Blow"),B2-C2,"")

And copy both down as far as required.