Getting data from Word table to Excel file

[jomelendez]

I have 33,990 Word files. Each of these files is just a table with different values. I want to copy specific cells values from each of these tables and exported to a Excel file.

 

[VoG]

Well I have this code that I think I picked up from this board:

Sub ImportWordTable()
Dim wdDoc As Object, wdFileName As Variant
Dim TableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel
wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")
If wdFileName = False Then Exit Sub '(user cancelled import file browser)
Set wdDoc = GetObject(wdFileName) 'open Word file
With wdDoc
    TableNo = wdDoc.tables.Count
    If TableNo = 0 Then
        MsgBox "This document contains no tables", vbExclamation, "Import Word Table"
    ElseIf TableNo > 1 Then
        TableNo = InputBox("This Word document contains " & TableNo & " tables." & vbCrLf & _
"Enter table number of table to import", "Import Word Table", "1")
    End If
    With .tables(TableNo)
        'copy cell contents from Word table cells to Excel cells
        For iRow = 1 To .Rows.Count
            For iCol = 1 To .Columns.Count
                Cells(iRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
            Next iCol
        Next iRow
    End With
End With
Set wdDoc = Nothing
End Sub

But clearly you don't want to run this manually 34,000 times. So you will need to give more information like: where the Word files are stored, the table number(s) in the document(s) and the cells in those tables. Then hopefully somebody can adapt the code.

 

[jomelendez]

Thanks for your prompt reply. Will start working on this tomorrow morning.