get formulas to skip columns

[AZA724]

I need to be able to quickly copy formulas on sheet1 by dragging but excel doesn't recognize the
sequence e.g.

CELL D56 =IF(OR(B56=""),"",IF(OR(Sheet2!E32=Sheet1!B56,Sheet2!E32=0),"OK","ERROR"))
CELL D57 =IF(OR(B57=""),"",IF(OR(Sheet2!G32=Sheet1!B57,Sheet2!G32=0),"OK","ERROR"))
CELL D58 =IF(OR(B58=""),"",IF(OR(Sheet2!I32=Sheet1!B58,Sheet2!I32=0),"OK","ERROR"))

How do i copy down without typing each one individually.

 

[navic]

Try

=IF(B56="","",IF(OR(INDIRECT("Sheet2!E"&INT(ROW($A93)/3)+1)=B56,INDIRECT("Sheet2!E"&INT(ROW($A93)/3)+1)=0),"OK","ERROR
=IF(B57="","",IF(OR(INDIRECT("Sheet2!G"&INT(ROW($A93)/3)+1)=B57,INDIRECT("Sheet2!G"&INT(ROW($A93)/3)+1)=0),"OK","ERROR"))
=IF(B57="","",IF(OR(INDIRECT("Sheet2!I"&INT(ROW($A93)/3)+1)=B58,INDIRECT("Sheet2!I"&INT(ROW($A93)/3)+1)=0),"OK","ERROR"))

Select three cells and copy down.

 

[navic]

My apologies
The last formula should start with
=IF(B58="",""

 

[Special-K99]

Avoiding INDIRECT solution

=IF(B56="","",IF(OR(INDEX(Sheet2!E32:ZZ32,1,(ROWS($1:1)-1)*3+1)=Sheet1!B56,INDEX(Sheet2!E32:ZZ32,1,(ROWS($1:1)-1)*3+1)=0),"OK","ERROR"))
and copy down

Replace ZZ32 with whatever column is last on Sheet2

 

[navic]

Avoiding INDIRECT solution2

Hi @Special-K99
If I understood OP well, the first three formula should return the result from the Row 32.
Then all three formulas should be copied down.
Regards

 

[Special-K99]

Hi @Special-K99
If I understood OP well, the first three formula should return the result from the Row 32.
Then all three formulas should be copied down.
Regards

Oh yep, could be that.

 

[jasonb75]

Maybe one of us is right

=IF(B56="","",IF(OR(INDEX(Sheet2!$32:$32,(ROWS(D$56:D56)-1)*2+5)=CHOOSE({1,2},B56,0)),"OK","ERROR"))

 

[AZA724]

Maybe one of us is right

=IF(B56="","",IF(OR(INDEX(Sheet2!$32:$32,(ROWS(D$56:D56)-1)*2+5)=CHOOSE({1,2},B56,0)),"OK","ERROR"))

Thank you this worked perfectly now i just need to understand it so I can use it for other spreadsheets