Generating a list of Dates using nested array inside SEQUENCE function?

[des378]

Hello,

I am trying to generate a list of dates with different intervals using an array inside of a single SEQUENCE function. How do I do this? Cell references are in bracket below and the results I'm looking for.

Ex:

Start Date End Date Day Interval
(A1) 2024-02-15 (B1) 2024-03-07 (C1) 7
(A2) 2024-02-23 (B2) 2024-03-22 (C2) 14


Looking to generate with SEQUENCE function this result:

2024-02-15
2024-02-22
2024-02-29
2024-03-07
2024-02-23
2024-03-08
2024-03-22

Basically it generates a list of values going through each start date in the array (A1:A2) and their respective interval (C1:C2). I am trying to use one instance of the SEQUENCE function to do this nesting arrays inside instead of using a SEQUENCE function for each start date. Any ideas?

Thank you in advance.

 

[Fluff]

Hi & welcome to MrExcel.
How about

Fluff.xlsm
	A	B	C
1	15/02/2024	07/03/2024	7
2	23/02/2024	22/03/2024	14
3
4
5	15/02/2024
6	22/02/2024
7	29/02/2024
8	07/03/2024
9	23/02/2024
10	08/03/2024
11	22/03/2024
12
Data

Cell Formulas
Range	Formula
A5:A11	A5	=DROP(REDUCE("",SEQUENCE(ROWS(A1:A2)),LAMBDA(x,y,LET(a,INDEX(A1:A2,y),c,INDEX(C1:C2,y),VSTACK(x,SEQUENCE((INDEX(B1:B2,y)-a)/c+1,,a,c))))),1)
Dynamic array formulas.

 

[Cubist]

Another option.

Book1
	A	B	C
1	2/15/24	3/7/24	7
2	2/23/24	3/22/24	14
3
4
5	2/15/24
6	2/22/24
7	2/29/24
8	3/7/24
9	2/23/24
10	3/8/24
11	3/22/24
Sheet1

Cell Formulas
Range	Formula
A5:A11	A5	=LET(m,(B1:B2-A1:A2)/C1:C2+1,s,SEQUENCE(1,MAX(m)),TOCOL(IFS(m>=s,A1:A2+(s-1)*C1:C2),2))
Dynamic array formulas.