function to return two 2D arrays

[RAYLWARD102]

Have many working functions returning one 2D array; wondering how I could return
2x 2D arrays? Example doesn't work; intended to show you what I'm trying to do

Sub testFunction()
    Dim t As Variant
    Dim a As Variant
    Dim b As Variant
    Dim j() As Variant

    ReDim t(0 To 2, 0 To 2) '2d array

    j = SomeFunction(t)

    a = j(0)
    b = j(1)
    
End Sub

Function SomeFunction(Input2DArray As Variant) As Variant()
    ReDim SomeFunction(0 To 1)
    SomeFunction(0) = Input2DArray
    SomeFunction(1) = Input2DArray
End Function

 

[LockeGarmin]

Here are a few ways. The first SomeFunction will be compatible with your testFunction.

Function SomeFunction(Input2DArray As Variant) As Variant()
    Dim Arr As Variant
    
    ReDim Arr(0 To 1)
    Arr(0) = Input2DArray
    Arr(1) = Input2DArray
    
    SomeFunction = Arr
End Function

Function SomeFunction2(Input2DArray As Variant) As Collection
    Dim Col As Variant
    
    Set Col = New Collection
    Col.Add Input2DArray
    Col.Add Input2DArray
    
    Set SomeFunction2 = Col
End Function

Function SomeFunction3(Input2DArray As Variant) As Variant()
    Dim Arr As Variant
    Dim x As Long
    Dim y As Long
    
    ReDim Arr(LBound(Input2DArray, 1) To UBound(Input2DArray, 1), _
              LBound(Input2DArray, 2) To UBound(Input2DArray, 2), _
              0 To 1)
    
    For x = LBound(Arr, 1) To UBound(Arr, 1)
        For y = LBound(Arr, 2) To UBound(Arr, 2)
            Arr(x, y, 0) = Input2DArray(x, y)
            Arr(x, y, 1) = Input2DArray(x, y)
        Next y
    Next x
    
    SomeFunction3 = Arr
End Function