Formula to Sum with Offset Function

[xcellrodeo]

Hi to the brilliant MrExcel Community,
I was wondering if I could get some help with the following issue I am having.
I have a large data set in Excel (Office 365 vs) with ca 27000 rows and around 50 columns.
What I would like to do is use a slicker method of summing up by Year.
Currently I am using loads of SUMIF statements in one cell to sum , by row, all adjacent Columns which have say year "2021" in them.
So for example:
Against each product, I have two columns i.e due date followed by a cost column.
From Columns M to CZ there are loads of products each with 2 columns. They are consistent in that the first is always the due date followed by the cost column which is the adjacent one.
Each product is displayed on a different row
What I want to do is create a SUMIF formula against each product that looks in say Row 3 and Columns M to CZ and find the criteria year i.e "2022" and then returns a sum of all the values in adjacent columns in same row, effectively offset by one column to the right of the year date. However, if the due date column matches the year search criteria but the cost in adjacent column is text then it should ignore this and move on to next.

Hope this makes sense.

Any help would be muchly appreciated.
Thanks

 

[xcellrodeo]

Sorry just to clarify...
Currently I am using loads of SUMIF statements in one cell to sum , by row, all adjacent Columns which have say year "2021" in them.
So for example:
Against each product group (Col.A), I have a range of Products (Col.M-CZ) of which each product has two columns i.e due date followed by a cost column.
They are consistent in that the first is always the due date followed by the cost column which is the adjacent one.
Each product group is displayed on a different row
What I want to do is create a SUMIF formula against each product group that looks in say Row 3 and Columns M to CZ and find the criteria year i.e "2022" and then returns a sum of all the values in adjacent columns in same row, effectively offset by one column to the right of the year date. However, if the due date column matches the year search criteria but the cost in adjacent column is text then it should ignore this and move on to next.

Hope this makes sense.

Any help would be muchly appreciated.
Thanks

 

[xcellrodeo]

Any ideas?

 

[StephenCrump]

Any ideas?

I suggest you'd get more help if you posted your layout.

Is this along the right lines?

	A	B	C	D	E	F	G	H	I	J	K	L	M
1				Product A		Product B		Product C		Product D		Product E
2	SumYear	Result		Year	Cost	Year	Cost	Year	Cost	Year	Cost	Year	Cost
3	2021	$912		2021	$123	2022	$456	2021	SomeText	2023	$2,021	2021	$789
Sheet1

Cell Formulas
Range	Formula
B3	B3	=SUM(FILTER(E3:M3,(D3:L3=A3)*(MOD(SEQUENCE(,COLUMNS(D33:L33)),2)=1),0))

 

[xcellrodeo]

Thanks StephenCrump, that's great. Yes I see your point about the data table. Note made for next time.
Just so I understand, why did you put 'COLUMNS(D33:L33)' in the formula? was this intentional as this doesnt appear to relate to the data rows refered to above?
If you could clarify this point that would be greatly appreciated, thanks

 

[StephenCrump]

Just so I understand, why did you put 'COLUMNS(D33:L33)' in the formula? was this intentional as this doesnt appear to relate to the data rows refered to above?

Sorry, I meant to type COLUMNS(D3:L3). But the key part is D:L, so the formula still works with the typo 33, although not if I subsequently delete Row 33!

The screenshot below shows why I included this component.

In the first example, I am confident I won't find "Jo" in the Cost columns, hence a simple formula will suffice.
The second illustrates the problem when the search year 2021 also appears as a Cost.
The third shows the fix - I have switched to the simpler ISODD rather than using MOD 2.

	A	B	C	D	E	F	G	H	I	J	K	L	M
1				Product A		Product B		Product C		Product D		Product E
2	SumYear	Result		Year	Cost	Year	Cost	Year	Cost	Year	Cost	Year	Cost
3	Jo	$912		Jo	$123	Sam	$456	Jo	SomeText	Sue	$2,021	Jo	$789
4
5	2021	$2,933		2021	$123	2022	$456	2021	SomeText	2023	$2,021	2021	$789
6	2021	$912		2021	$123	2022	$456	2021	SomeText	2023	$2,021	2021	$789
Sheet2

Cell Formulas
Range	Formula
B3,B5	B3	=SUM(FILTER(E3:M3,D3:L3=A3,0))
B6	B6	=SUM(FILTER(E6:M6,(D6:L6=A6)*ISODD(SEQUENCE(,COLUMNS(D6:L6))),0))