Formula to return unique values based on 4 criteria

[thomasuponor]

Hello everybody,

I want to count unique value with following formula, which usually works, but does not for this task. The extra add on is Data'!$AA:$AA;"*Dahl*" (I believe this is the reason it's not working)

=SUM(--(FREQUENCY(IF(('Visit Data'!$AD:$AD="Distributor")*(ISNUMBER(SEARCH('Visit Data'!$AG:$AG;"Visit")))*(ISNUMBER(SEARCH('Visit Data'!$V:$V;"Kim")))*(ISNUMBER(SEARCH('Visit Data'!$AA:$AA;"*Dahl*")));MATCH('Visit Data'!$AA:$AA;'Visit Data'!$AA:$AA;0));ROW('Visit Data'!$AA:$AA)-ROW('Visit Data'!$AA$3)+1)>0))

Anyone able to provide help here?
Thx

 

[KRice]

Are you sure this approach has usually worked? The SEARCH functions appear to have the arguments in reverse order. If you want a count where all of those conditions are met in the same row, then try:
=COUNTIFS('Visit Data'!$AD:$AD,"*Distributor*",'Visit Data'!$AG:$AG,"*Visit*",'Visit Data'!$V:$V,"*Kim*",'Visit Data'!$AA:$AA,"*Dahl*")

 

[DonkeyOte]

x-posted at EF.com but, if you have access to O365 functions you could use UNIQUE + FILTER as an alternative, i.e.:

=COUNTA(UNIQUE(FILTER('Visit Data'!$AA:$AA;ISNUMBER(('Visit Data'!$AD:$AD="Distributor")*SEARCH("Visit";'Visit Data'!$AG:$AG)*SEARCH("Kim";'Visit Data'!$V:$V)*SEARCH("Dahl";'Visit Data'!$AA:$AA))))

 

[thomasuponor]

Are you sure this approach has usually worked? The SEARCH functions appear to have the arguments in reverse order. If you want a count where all of those conditions are met in the same row, then try:
=COUNTIFS('Visit Data'!$AD:$AD,"*Distributor*",'Visit Data'!$AG:$AG,"*Visit*",'Visit Data'!$V:$V,"*Kim*",'Visit Data'!$AA:$AA,"*Dahl*")

Yes, have been using this formula for a while and it's working. Using the =countifs does not return the unique values.

 

[thomasuponor]

x-posted at EF.com but, if you have access to O365 functions you could use UNIQUE + FILTER as an alternative, i.e.:

=COUNTA(UNIQUE(FILTER('Visit Data'!$AA:$AA;ISNUMBER(('Visit Data'!$AD:$AD="Distributor")*SEARCH("Visit";'Visit Data'!$AG:$AG)*SEARCH("Kim";'Visit Data'!$V:$V)*SEARCH("Dahl";'Visit Data'!$AA:$AA))))

Unfortunately, I am nut using 0365.

 

[DonkeyOte]

=SUM(--(FREQUENCY(IF(ISNUMBER(('Visit Data'!$AD:$AD="Distributor")*SEARCH("Visit";'Visit Data'!$AG:$AG)*SEARCH("Kim";'Visit Data'!$V:$V)*SEARCH("Dahl";'Visit Data'!$AA:$AA));MATCH('Visit Data'!$AA:$AA;'Visit Data'!$AA:$AA;0));ROW('Visit Data'!$AA:$AA))>0))
confirmed with CTRL + SHIFT + ENTER

however, you shouldn't use entire column references with Arrays -- use either (non-volatile) Dynamic Named Ranges, or Tables.

 

[KRice]

What result do you get with the formula I posted? Here is an example where the count is shown in U1 where each text string is found on the same row in the specified columns. Is that what you want to count?

Book1
	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG
1	Count -->	2
2											acme			Visit
3
4			Jung Kim					Abe Dahlberg			a Distributor here			Visit
5			Andy Kim					Obdahl Lu			a distributor there			A nice visit here
6			Jacob					John			not a dist			A nice visit there
Visit Data

Cell Formulas
Range	Formula
U1	U1	=COUNTIFS('Visit Data'!$AD:$AD,"*Distributor*",'Visit Data'!$AG:$AG,"*Visit*",'Visit Data'!$V:$V,"*Kim*",'Visit Data'!$AA:$AA,"*Dahl*")

Did you convert the commas to semicolons?...it looks like you have that preference set?

 

[DonkeyOte]

correction:

=SUM(--(FREQUENCY(IF(ISNUMBER(SEARCH("Visit";'Visit Data'!$AG:$AG)*SEARCH("Kim";'Visit Data'!$V:$V)*SEARCH("Dahl";'Visit Data'!$AA:$AA)/('Visit Data'!$AD:$AD="Distributor"));MATCH('Visit Data'!$AA:$AA;'Visit Data'!$AA:$AA;0));ROW('Visit Data'!$AA:$AA))>0))
confirmed with CTRL + SHIFT + ENTER

 

[KRice]

It looks like what @DonkeyOte posted works fine. I still don't understand why the non-array formula I suggested won't work, unless the commas were left unchanged. It also appears that you want only instances where column AD contains "Distributor" rather than that string found anywhere, so a revised version would be:
=COUNTIFS('Visit Data'!$AD:$AD;"Distributor";'Visit Data'!$AG:$AG;"*Visit*";'Visit Data'!$V:$V;"*Kim*";'Visit Data'!$AA:$AA;"*Dahl*")

 

[DonkeyOte]

Hi @KRice, the issue with the COUNTIFS would be duplicates of any "Dahl" variant in AA:AA.
(you could create a SUMPRODUCT/COUNTIFS based alternative to the FREQUENCY array -- and tbh, as I coded it there won't be much difference in performance... if you separate the various Boolean tests into discrete / pre-emptive IFs the Array will likely perform better, I would say.