formula to only check filtered results

[SQUIDD]

Hi All

so i use formula like this

=COUNTA('MY SELECTIONS'!D:D)-1

But lets say a filtered column D, is there a way th formula would only return the newly filtered data?

Thanks in advance

Dave

 

[Jonmo1]

Try SUBTOTAL

=SUBTOTAL(103,'MY SELECTIONS'!D:D)-1

 

[SQUIDD]

Hi Jonmo1

That change of formula worked great.
Sorry, but i should perhaps explained, when i said i have formula LIKE above, i have similar formula also.

So im not sure ir subtotal will work for all, i will have a play around.

this is all my formula

=COUNTIFS('MY SELECTIONS'!G:G,"1ST")

=AVERAGE('MY SELECTIONS'!O:O)

=AVERAGEIF('MY SELECTIONS'!G:G,"1ST",'MY SELECTIONS'!O:O)

thanks again

dave

 

[Jonmo1]

Well we can only work with information given...

Add a helper column in the My Selections sheet, say column Q, and assuming row 1 is headers.
In Q2 and filled down put
=SUBTOTAL(103,G2)

Then use that column in your countifs / Averagifs formulas

=COUNTIFS('MY SELECTIONS'!G:G,"1ST",'MY SELECTIONS'!Q:Q,1)

=AVERAGEIF('MY SELECTIONS'!Q:Q,1,'MY SELECTIONS'!O:O)

=AVERAGEIFS('MY SELECTIONS'!O:O,'MY SELECTIONS'!G:G,"1ST",'MY SELECTIONS'!Q:Q,1)