Formula to make combination of elements given possible variables?

[gifariz]

I need a formula to make 2D array of combination of a number of elements given an array of possible variables. Below is the sample input output:
ne = 2
x = {a;b;c}
out = {a,a; a,b; a,c; b,a; b,b; b,c; c,a; c,b;, c,c}

ne is number of elements as integer, x is list of variables as 1d array of any length. I would like to have formula without MAKEARRAY, LAMBDA or other slow functions. This is supposed to be an easy combinatoric problem, but I can't find elegant solution. Below is my attempt:
=LET(ne,A1,x,B1:B3,nx,COUNTA(x),i,SEQUENCE(nx^ne,ne,0),r,INT(i/ne)+1,c,MOD(i,ne)+1,comb,TEXT(BASE(SEQUENCE(nx^ne,,0),nx),REPT("0",ne)),INDEX(x,VALUE(MID(INDEX(comb,r),c,1))+1))
It works but too complicated.

Could anyone help? Or maybe someone has made the lambda function in lambda sub-forum? Thanks in advance.

 

[kvsrinivasamurthy]

Try.

=LET(x,B1:B3,x&","&TRANSPOSE(x))

 

[hagia_sofia]

Hello, would this work for you:

=LET(
ne,A1,
x,B1:B3,
nx,COUNTA(x),
seq,SEQUENCE(nx),
all,MOD(TRUNC(SEQUENCE(nx^ne,,0)/nx^(ne-SEQUENCE(,ne))),nx)+1,
XLOOKUP(all,seq,x))

 

[gifariz]

Try.

=LET(x,B1:B3,x&","&TRANSPOSE(x))

Sorry but this is other type of combination. My problem would make number of columns of the output equals to first input (element number).

 

[gifariz]

Hello, would this work for you:

=LET(
ne,A1,
x,B1:B3,
nx,COUNTA(x),
seq,SEQUENCE(nx),
all,MOD(TRUNC(SEQUENCE(nx^ne,,0)/nx^(ne-SEQUENCE(,ne))),nx)+1,
XLOOKUP(all,seq,x))

This is it! Thank you very much!
I recall using this equation many times but it's hard for me to intuit it from scratch.

One thing, looks like using INDEX is more efficient, no lookup
=LET(ne,A1,x,B1:B3,nx,COUNTA(x),INDEX(x,MOD(TRUNC(SEQUENCE(nx^ne,,0)/nx^(ne-SEQUENCE(,ne))),nx)+1))

 

[felixstraube]

Just for fun, another option:

=LET(ne,A1, x, B1:B4, lx, COUNTA(x), INDEX(x, MID(BASE(SEQUENCE(lx^ne,,0), lx, ne), SEQUENCE(,ne), 1)+1))