Formula to Calculate uplift based on MAX Value

[Bravo33]

I have 4 columns with costs for 2015,2016, 2017 & MAX Value
I want to apply and % uplift to the MAX value column but this could be in any of the 3 columns.
The % Uplift varies dependent upon what year the MAX value is in.

Col 1; Col 2; Col 3; Col 4
2015; 2016; 2017; Max Value
8.07%;6.65%;3.95%;
£500; £650; £525; =£650+6.65%

Many thanks,

 

[louisH]

Hi,

If col1 = A, col2 = B , etc.
And row starts at 1:

=MAX(A3:B3)*(1+OFFSET(A2,0,MATCH(MAX(A3:B3),A3:B3,0)-1))

 

[steve the fish]

Heres one way if the max is always distinct:

=SUMPRODUCT(--(A3:C3=MAX(A3:C3)),1+A2:C2,A3:C3)

Or another if you want the first max if it isnt distinct:

=MAX(A3:C3)*(1+INDEX(A2:C2,MATCH(MAX(A3:C3),A3:C3,0)))

Or maybe this if you want the last max if it isnt distinct:

=LOOKUP(2,1/(A3:C3=MAX(A3:C3)),(1+A2:C2)*A3:C3)

 

[Bravo33]

Thanks All, greatly appreciated. Steve's, "=MAX(A3:B3)*(1+OFFSET(A2,0,MATCH(MAX(A3:B3),A3:B3,0)-1))"
Worked a treat!!