Formula Not Working

[MrDB4Excel]

I use the following formula: =SUM(G3+[@Income]-[@Debits]) in a worksheet that gets data from another worksheet.
I have tinkered with this issue for too many hours and cannot seem to get it working.
As you can see in the XL2bb Mini Sheet, this formula works in cell G3 but the next cell down, G4 returns with #VALUE!
I thought using helper columns H, I, J, & K would solve the issue, but to no avail.
What am I missing here?
Any help will be much appreciated.

BogusAutomatedMonthlyBudget.xlsx
	A	B	C	D	E	F	G	H	I	J	K
1	Month	Date	Description	Income	Debits	Balance
2	1	Jan/06/2022	January Starting Balance	$1,000.00		$1,000.00
3	1	Jan/06/2022	Pension Deposit	$1,000.00		$2,000.00
4	1	Jan/06/2022	Medicare Part B		$100.00	#VALUE!		$100.00	$100.00	$1,000.00	$1,000.00
5	1	Jan/06/2022	Medicare Part D		$100.00	#VALUE!		$100.00	$100.00
6	1	Jan/07/2022	Rent		$600.00	#VALUE!		$600.00	$600.00
7	1	Jan/07/2022	Electricity		$120.00	#VALUE!		$120.00	$120.00
8	1	Jan/08/2022	Verizon		$100.00	#VALUE!		$100.00	$100.00
9	1	Jan/08/2022	Car Payment		$100.00	#VALUE!		$100.00	$100.00
10						#VALUE!
11						#VALUE!
12						#VALUE!
13						#VALUE!
14						#VALUE!
15						#VALUE!
2022

Cell Formulas
Range	Formula
A2:A15	A2	=IF((ISERROR(MONTH('2022'!$B2)))," ",(MONTH('2022'!$B2)))
B2:B15	B2	=IF(ISBLANK([BogusEasyAccounting2022.xlsx]Expenses!$B3)," ",([BogusEasyAccounting2022.xlsx]Expenses!$B3))
C2:C15	C2	=IF(ISBLANK([BogusEasyAccounting2022.xlsx]Expenses!$C3)," ",([BogusEasyAccounting2022.xlsx]Expenses!$C3))
D3	D3	=K4
F2	F2	=[@Income]
F3:F15	F3	=SUM(F2+[@Income]-[@Debits])
D4:D15	D4	=IF(ISBLANK([BogusEasyAccounting2022.xlsx]Expenses!$E5)," ",([BogusEasyAccounting2022.xlsx]Expenses!$E5))
E4	E4	=I4
H4:H15,E5:E15	E5	=IF(ISBLANK([BogusEasyAccounting2022.xlsx]Expenses!$D6)," ",([BogusEasyAccounting2022.xlsx]Expenses!$D6))
I4:I15,K4:K15	I4	=IF((ISERROR(VALUE(H4)))," ",(VALUE(H4)))
J4:J15	J4	=IF(ISBLANK([BogusEasyAccounting2022.xlsx]Expenses!$E4)," ",([BogusEasyAccounting2022.xlsx]Expenses!$E4))

Supporting Sheet:

BogusEasyAccounting2022.xlsx
	A	B	C	D	E	F
2	Month	Date	Description	Debits	Income	Balance
3	1	Jan/06/2022	January Starting Balance			$1,000.00
4	1	Jan/06/2022	Pension Deposit		$1,000.00	$2,000.00
5	1	Jan/06/2022	Medicare Part B	$100.00		$1,900.00
6	1	Jan/06/2022	Medicare Part D	$100.00		$1,800.00
7	1	Jan/07/2022	Rent	$600.00		$1,200.00
8	1	Jan/07/2022	Electricity	$120.00		$1,080.00
9	1	Jan/08/2022	Verizon	$100.00		$980.00
10	1	Jan/08/2022	Car Payment	$100.00		$880.00
11	1					$880.00
12	1					$880.00
13	1					$880.00
14	1					$880.00
15	1					$880.00
Expenses

Cell Formulas
Range	Formula
A3:A15	A3	=MONTH(B3)
F4:F15	F4	=SUM(F3+[@Income]-[@Debits])

 

[Fluff]

It isn't working as you have cells that contain "" which is text & you cannot add or subtract text.
Try

=F3+N([@Income])-N([@Debits])

 

[Phuoc]

Try this

=SUM(G3,[@Income])-SUM([@Debits])

 

[MrDB4Excel]

Many Thanks, Fluff. Perfect solution.
You have made my day.
Hope your day is good.
Stay safe

 

[Fluff]

Glad we could help & thanks for the feedback.

 

[MrDB4Excel]

Try this

=SUM(G3,[@Income])-SUM([@Debits])

Thanks, Phuoc, but I used =F3+N([@Income])-N([@Debits]) and it does what I need. Regardless, I will try your formula anyway just to see how it works.

 

[MrDB4Excel]

Try this

=SUM(G3,[@Income])-SUM([@Debits])

Hello Phuoc, I tried your formula and it works equally well. Thank you