Formula Help

[RamyJo]

While working I created a spreadsheet that saves me alot of time daily but I'm stuck on a formula I need for the data in one workbook. I have a list of names in Cell A. That same list is broken down into different groups in other cells (Cells C, E, G, M). I am wanting a formula that I can enter into the other cells so that when i delete a name in column A it will delete the same name in the other cell it's in and then leave the other cell blank. I tried put the formula =a2, =a3. etc... in column c but when i deleted the info in column a it put a 0 in cell c...

Thanks for any and all help.

 

[Joe4]

Any cell can only have either a hard-coded value, or a formula, but NEVER both at the same time.
If the "values" (C, E, G, M) can be derived from column A, then it is easy to make them return nothing when column A is nothing, i.e.

=IF(A2="","",formula)

Otherwise, the only way to do what you want would require the use of VBA.
Are you open to that type of solution?

 

[RamyJo]

Yes I am open to a VBA solution. I have used them before but just don't know how to write them (yet!).

I'm wanting to find some kind of online training or classes to take to learn all the ins and outs of Excel.

 

[Joe4]

Right-click on the sheet tab name at the bottom of the screen, select "View Code", and copy/paste this code in the VBA Editor window that pops up:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range
    Dim cell As Range
    
'   See if any cells updated in column A
    Set rng = Intersect(Target, Columns("A:A"))
    If rng Is Nothing Then Exit Sub
    
'   Loop through all cells in column A
    Application.EnableEvents = False
    For Each cell In rng
'       See if row>1 and value is blank
        If cell.Row > 1 And cell.Value = "" Then
'           Clear columns C, E, G, and M
            cell.Offset(0, 2).ClearContents
            cell.Offset(0, 4).ClearContents
            cell.Offset(0, 6).ClearContents
            cell.Offset(0, 12).ClearContents
        End If
    Next cell
    Application.EnableEvents = True

End Sub