Formula for Result table to show name only once, this is taken from main data table with lots repeat name records

[Leicester City Fox]

Hi there

I have a result table that shows the names people and their point totals and this is takes this information from the main data table:

Result Table example :

Name (Column A) (Points total Colum B)

Dave 10

Sue 5

Paul 15

(New Name only Added if unique once added to main data table and or not repeat of the names already recorded)


These names are come from the main data table example below with repeat names



Name Points

Sue 2

Dave 5

Paul 10

Dave 5

Sue 3

Paul 5



I want my result table only to state the unique name once or new ones that are added to the main data table and no matter how main repeats they get.

Any ideas of a simple formula that will only recorded names from the main table into the results table once and news that are not repeats.

Many Thanks

Leicester Fox

 

[Fluff]

How about

=IFERROR(INDEX(Main!A2:A100,AGGREGATE(15,6,(ROW(Main!A2:A100)-ROW(Main!A2)+1)/(ISNA(MATCH(Main!A2:A100,A$1:A1,0)))/(Main!A2:A100<>""),1)),"")

 

[Peter_SSs]

I would suggest turning the main table into a formal Excel table, if not already. This option is on the 'Insert' ribbon tab.

Then use formulas like columns D:E for the results table. Drag them down as far as you might ever need. As new names are added in the main table, they will appear (once) in the results table.

22 04 19.xlsm
	A	B	C	D	E
1	Main			Results
2	Name	Points		Name	Points
3	Sue	2		Sue	5
4	Dave	5		Dave	10
5	Paul	10		Paul	15
6	Dave	5
7	Sue	3
8	Paul	5
Unique Names

Cell Formulas
Range	Formula
D3:D8	D3	=IFERROR(INDEX(Table1[Name],MATCH(0,INDEX(COUNTIF($D$2:D2,Table1[Name]),0),0)),"")
E3:E8	E3	=IF(D3="","",SUMIF(Table1[Name],D3,Table1[Points]))

 

[Leicester City Fox]

Hi Peter

Good Afternoon

I am very grateful the formula worked a treat and works well with tables.

I hope you and your family have a good Easter Break.

Many Thanks & Stay Safe

The Leicester Fox

 

[Peter_SSs]

You're welcome. Glad we could help. Thanks for the follow-up.