Formatting particular character in a string

[smartkrips]

Hello Friends,

Is it possible to format particular character in a string...

For example: String = Pipe Sleeve I|32/19

i want to find character '|' in a string and make it bold and red in color...

Like: Pipe Sleeve I|32/19

w/o using Micro?

if not, may I get micro example, please?


Rgds,
KK

 

[pgc01]

Hi KK

No, to format the character you must do it manually or run a macro.

For ex., assuming there may be several "|" characters in a cell, this would do it for A1:A10.

Sub PipeStrong()
Dim r As Range, rC As Range
Dim j As Long, k As Long
Const sPipe As String = "|"

Set r = Range("A1:A10")

For Each rC In r
    k = 1
    Do While True
        j = InStr(k, rC.Value, sPipe)
        If j = 0 Then Exit Do
        With rC.Characters(j, 1).Font
            .Bold = True
            .Color = vbRed
        End With
        k = j + 1
    Loop
Next rC
End Sub

 

[smartkrips]

Hello PGC,

Thanks for your answer and macro too...

This really helps and problem solved.


Rgds,
KK

 

[pgc01]

You're welcome. Thanks for the feedback.

Remark: I forgot to say in my post that I assumed the text in the cell is a constant, not the result of a formula.