Format User Form Controls From within another module

[Peter Ren]

Hi, I have some code that I used to format the controls of a form. I know want to re-use that code to format other/different User Forms

My code is:

Private Sub UserForm_Initialize()
    Dim ctrl As Control
    
   'Loop Through each LABEL control on UserForm->frmTxAdd
    For Each ctrl In Me.Controls
        If TypeName(ctrl) = "Label" Then
            ctrl.BackColor = RGB(241, 248, 233)
        End If
    Next ctrl
End Sub

I have replaced the above FOR loop with:
Call FormColourGreen(Me.Name)

In Module 1, I have the following code (doesn't work)

Sub FormColourGreen(FrmName)
    Dim ctrl As Control
    
    '   Set background colour - very light green
    'Loop Through each LABEL control on UserForm
    For Each ctrl In frmName.Controls
        If TypeName(ctrl) = "Label" Then
            ctrl.BackColor = RGB(241, 248, 233)
        End If
    Next ctrl
End Sub

Your help will be very much appreciated Many Thanks

 

[Norie]

Instead of passing the name of the userform to the other sub pass the actual userform itself.

Userform code

Private Sub UserForm_Initialize()
    Call FormColourGreen(Me)
End Sub

Module code

Sub FormColourGreen(Frm As Variant)
Dim ctrl As Control

    ' Set background colour - very light green
    ' Loop Through each LABEL control on UserForm frm
    
    For Each ctrl In Frm.Controls
        If TypeName(ctrl) = "Label" Then
            ctrl.BackColor = RGB(241, 248, 233)
        End If
    Next ctrl

End Sub

 

[mikerickson]

Or you could use a sub like this to set the default values of the Labels, and not have to set it in the Initialize event.

Sub MakeUFDefaultGreen()
    Dim oneControl As Object
    
    With ThisWorkbook.VBProject.VBComponents("Userform1").Designer: Rem adjust
        For Each oneControl In .Controls
            If TypeName(oneControl) = "Label" Then
                oneControl.BackColor = RGB(241, 248, 233)
            End If
        Next oneControl
    End With
End Sub

 

[Peter Ren]

Instead of passing the name of the userform to the other sub pass the actual userform itself.

Thanks Norrie worked a treat, you have helped an old man who is trying o use his brain - use it or lose it apparently