Format every fouth row height

[MaleNurse]

I have a number of large spread- sheets. I need to format the row height of every fourth row to 24.00
I have the macro below which doesn't work. Can anyone fix it please?

Sub Height()
X = 0
Do
X = X + 4
Rows(X).RowHeight = 24
Loop Until X = 1000
End Sub


Thanks Steve..

 

[Fennek]

Hi,

the search-engine says:

Sub Main
for i = 1 to 12 step 4
     rows(i).rowheight = 24 
next i
End Sub

regards

 

[Vbagreenhorn1]

Hi Steve,

your macro works fine! Why isnt it working?

 

[My Aswer Is This]

Try this:

Sub Row_Height()
Application.ScreenUpdating = False
Dim i As Long
    For i = 4 To 1000 Step 4
        Rows(i).RowHeight = 24
    Next
Application.ScreenUpdating = True
End Sub

 

[MaleNurse]

Hi Steve,

your macro works fine! Why isnt it working?

It is working now. However, it seems to start at random rows. Can I peg it to Row 5 then every subsequent 4th row will be set at the desired height.

 

[My Aswer Is This]

So you did not like my script?
Change

For i = 4 To 1000 Step 4

To:

For i = 5 To 1000 Step 4

It is working now. However, it seems to start at random rows. Can I peg it to Row 5 then every subsequent 4th row will be set at the desired height.

 

[Vbagreenhorn1]

Sub Height()
 X = 5
 Do
 Rows(X).RowHeight = 24
  X = X + 4
 Loop Until X > 1000
 End Sub

 

[MaleNurse]

Thank you that works fine. I have a glitch in the spread sheet down at about row 220 but the rest of the script is perfect.. Now I only have to copy it into 23 spread sheets.
Cheers

 

[My Aswer Is This]

If you wanted to do all 23 worksheets starting in sheet 1 you could use this script.
And it would do all 23 sheets at one time.
But you may have not liked my script since you ignored all my questions

Sub Row_Height()
'Modified 11-25-17 5:57 AM EST
Application.ScreenUpdating = False
Dim i As Long
Dim b As Long
    For b = 1 To 23
    
    With Sheets(b)
    For i = 5 To 1000 Step 4
        .Rows(i).RowHeight = 24
    Next
    End With
    Next
Application.ScreenUpdating = True
End Sub

 

[MARK858]

The below will change the height in every worksheet in the workbook where you have data in column A past row 4 in one go rather than looping through the rows one at a time.

Sub OtherRow()
    Dim LR As Long, i As Long
    Dim myRow As Range, mySht As Worksheet
    Application.ScreenUpdating = False

    For Each mySht In ActiveWorkbook.Worksheets

        With mySht
            LR = .Range("A" & Rows.Count).End(xlUp).Row
            If LR > 4 Then
                Set myRow = .Rows(1)
                For i = 5 To LR Step 4
                    Set myRow = Union(myRow, .Rows(i))
                Next i
                myRow.RowHeight = 24
            End If
        End With

    Next
    Application.ScreenUpdating = True
End Sub