Form Password

[cornishteeth]

How would you go about putting a password on a form only. I used this but my password is seen when I input it. Any way to allow the password to be entered with asterisks appearing vice the password.


Dim stDocName As String
Dim stLinkCriteria As String
Dim password As String


password = InputBox("Please enter password!")

If password = "security" Then ' type password
stDocName = "frmMainInput"
DoCmd.OpenForm stDocName, , , stLinkCriteria
Else
MsgBox "Incorrect password, plz re-enter", vbCritical, "Error"
End If
End Sub

 

[TheNoocH]

Copy and paste this code into a module named modPWAPI:
(i got this from the Excel Forums and it works like a charm)
Then pull it up using InputBoxDK rather than InputBox:
e.g. password = InputBoxDK("Please enter password!")
hope that helps...i haven't tried it in Access but works great in Excel

Option Explicit
'////////////////////////////////////////////////////////////////////
'Password masked inputbox
'Allows you to hide characters entered in a VBA Inputbox.
'
'Code written by Daniel Klann
'March 2003
'////////////////////////////////////////////////////////////////////


'API functions to be used
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long

Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long

Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _
(ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
ByVal dwThreadId As Long) As Long

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long

Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _
(ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

'Constants to be used in our API functions
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0

Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim RetVal
Dim strClassName As String, lngBuffer As Long

If lngCode < HC_ACTION Then
NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
Exit Function
End If

strClassName = String$(256, " ")
lngBuffer = 255

If lngCode = HCBT_ACTIVATE Then 'A window has been activated

RetVal = GetClassName(wParam, strClassName, lngBuffer)

If Left$(strClassName, RetVal) = "#32770" Then 'Class name of the Inputbox

'This changes the edit control so that it display the password character *.
'You can change the Asc("*") as you please.
SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
End If

End If

'This line will ensure that any other hooks that may be in place are
'called correctly.
CallNextHookEx hHook, lngCode, wParam, lParam

End Function

Public Function InputBoxDK(Prompt, Optional Title, Optional Default, Optional XPos, _
Optional YPos, Optional HelpFile, Optional Context) As String
Dim lngModHwnd As Long, lngThreadID As Long

lngThreadID = GetCurrentThreadId
lngModHwnd = GetModuleHandle(vbNullString)

hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)

InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
UnhookWindowsHookEx hHook

End Function

 

[mdmilner]

My first question is, what is it you're actually trying to do?
My second question is, have you looked at the built-in security features to Access? (Tools-Security-User and Group Permissions)

As summary, Access allows you to control access to each individual object (every table/query/form/report/etc) by granting access to 'login' id's. This is not the same thing as a database password. The level of control is similar to what Windows users first saw with the NT OS.
-
As an alternative, any textbox can be set with the password masking property. You can create a given startup form - users click a button, and it throws up a prompt (another form) for a (masked field) password.

Being cute, you could create your form that you want people to access with a password, but, hide ALL the objects on it (Visible=False) except for the password field. In the after_update event for the password textbox, have it evaluate the password and make the rest of the form visible (and hide the PW)


Mike