For loop with nested Do loop, For loop not working

[capson]

Hello,

I am trying to use a Do loop for the first time and having some difficulty

I want to exit the Do loop when

.Cells(irow, icol) = ""

and advance to the next row

My code only works for the irow = 2, it does not advance i.e. next irow does not seem to be read or executed

The For loop is not working and not sure why

The Do loop is giving me what I want

Thanks for any help on this

Sub testDoLoop()
Dim ws As Worksheet
Dim cnt As Long, irow As Long, icol As Long, LR As Long, LC As Long


Set ws = ThisWorkbook.Sheets("Elements")
      LC = 149
      LR = 276
    
  cnt = 1
  icol = 13
  With ws
    For irow = 2 To LR


     Do While icol <= LC
       If .Cells(irow, icol) <> "" Then
         .Cells(irow, icol).value = "sm-" & cnt & "|" & .Cells(irow, icol).value
         cnt = cnt + 1
         icol = icol + 9
       Else
       
        Exit Do
      End If
    Loop


  Next irow
End With


End Sub

 

[Norie]

When I run the code the For loop is definitely working.

Have you tried stepping through the code with F8 to see what's actually happening?

 

[Fluff]

Hia, both loops are working fine, the problem is your not re-setting icol after the do loop.
Add this line as shown

    Loop
   [COLOR=#0000ff] icol = 13
[/COLOR]
  Next irow

Another option is to use For each loops for both like this

    With ws
        For irow = 2 To LR
            For icol = 13 To LC Step 9
                If .Cells(irow, icol) <> "" Then
                    .Cells(irow, icol).Value = "sm-" & cnt & "|" & .Cells(irow, icol).Value
                    cnt = cnt + 1
                Else
                    Exit For
                End If
            Next icol
        Next irow
    End With

 

[JackDanIce]

If you want to switch to a nested For Loop, (which resets to 13 as @Fluff suggests), try:

Sub testDoLoop()

    Dim cnt     As Long
    Dim x       As Long
    Dim y       As Long
    Dim LR      As Long: LR = 276
    Dim LC      As Long: LC = 149
    
    Application.ScreenUpdating = False
    
    With Sheets("Elements")
        
        For x = 2 To LR
            For y = 13 To LC Step 9
                If Len(.Cells(x, y)) > 0 Then
                    .Cells(x, y).Value = "sm-" & cnt & "|" & .Cells(x, y).Value
                    cnt = cnt + 1
                End If
            Loop
        Next x
        
    End With
    
    Application.ScreenUpdating = True
    
End Sub

 

[capson]

Thank you all, that was very helpful in understanding different ways to do this

 

[Fluff]

Glad we could help & thanks for the feedback