FOR IF continual loop error

[Enzo_Matrix]

I am trying to get my table to insert a blank row after a set date, but this code is creating a continual loop that I need to break manually.

I'm not sure what I have done wrong, but can someone please help me correct this code or suggest something that would work better?

Sub InsrtRow()

Dim C As Range
    
    With Sheets("Weld")
       For Each C In .Range("G5", .Cells(Rows.Count, 7).End(xlUp))
            If C >= Date + 2 Then
                C.EntireRow.Insert , CopyOrigin:=xlFormatFromLeftOrAbove
            End If
        Next
    End With


End Sub

 

[sheetspread]

Write a for/next loop from the last row to the first instead, otherwise you have to adjust the counter each time to prevent repetition.

 

[Fluff]

When deleting/inserting rows you should always work bottom up, rather than top down.
try

Sub InsrtRow()

Dim i As Long
    
    With Sheets("Weld")
       For i = .Range("G" & Rows.count).End(xlUp).Row To 5 Step -1
            If Range("G" & i).Value >= Date + 2 Then
                Rows(i).EntireRow.Insert , CopyOrigin:=xlFormatFromLeftOrAbove
            End If
        Next i
    End With


End Sub

 

[Enzo_Matrix]

This works very well thank you,

it does however add a row for every date after the '>=Date +2'. I'm wondering if this can be done once instead of for each instance of the date range.
April 12 April 12
April 13 April 13

April 14 April 14
April 15
April 15 April 16

April 16...

I was also asked if this can be modified to only work for week days. Is that possible?

 

[Fluff]

Is this what you mean

Sub InsrtRow()

Dim cl As Range
    
    With Sheets("pcode")
       For Each cl In .Range("G5", .Range("G" & Rows.count).End(xlUp))
            If cl.Value >= Application.WorkDay(Date, 2) Then
                cl.EntireRow.Insert , CopyOrigin:=xlFormatFromLeftOrAbove
                Exit For
            End If
        Next cl
    End With
End Sub