First Monday of week one (not first monday of month)

[CaptArt]

Okay, here is a brain stumper. (for me anyway). SO, there are 52 weeks in a year. I need to find the first Monday of week 1, not necessarily of the month. For example, January 1, 2025 is a Wednesday. In payroll, it is Monday December 30, 2024. That is the first monday of 'week 1'. I have found a zillon ways to find January 6, 2025 (the first monday of january), but not for week 1.

 

[awoohaw]

maybe this

Book1
	A	B	C
1	Date	WeekNbr	Is 1st Mon Wk 1:
2	Sat 2024-12-28	52	FALSE
3	Sun 2024-12-29	52	FALSE
4	Mon 2024-12-30	1	TRUE
5	Tue 2024-12-31	1	FALSE
6	Wed 2025-01-01	1	FALSE
7	Thu 2025-01-02	1	FALSE
8	Fri 2025-01-03	1	FALSE
9	Sat 2025-01-04	1	FALSE
10	Sun 2025-01-05	1	FALSE
11	Mon 2025-01-06	2	FALSE
12	Tue 2025-01-07	2	FALSE
Sheet2

Cell Formulas
Range	Formula
B2:B12	B2	=WEEKNUM(A2,21)
C2:C12	C2	=AND(WEEKNUM(A2,21)=1,WEEKDAY(A2)=2)

 

[Phuoc]

Try this:

=WORKDAY.INTL(A1-1,1,"1110111")-3

 

[Phuoc]

Book1
	A	B
1	1/1/2024	1/1/2024
2	1/1/2025	30/12/2024
3	1/1/2026	29/12/2025
4	1/1/2027	4/1/2027
5	1/1/2028	3/1/2028
6	1/1/2029	1/1/2029
7	1/1/2030	31/12/2029
8	1/1/2031	30/12/2030
Sheet1

Cell Formulas
Range	Formula
B1:B8	B1	=WORKDAY.INTL(A1-1,1,"1110111")-3

 

[JEC]

Or (in A1 the year)

=DATE(A1,1,4)-WEEKDAY(DATE(A1,1,4),2)+1

It is al based on the fact (also in Phuocs' solution) that the first thursday is always in the new year.