Finding the last row to sort data

[DrH100]

I have the code below which was working fine

Application.ScreenUpdating = False
    Range("A12:BD30").Select
    Range("BD30").Activate
    ActiveWorkbook.Worksheets("Employer Database").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Employer Database").Sort.SortFields.Add Key:=Range _
        ("B12:B30"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
    With ActiveWorkbook.Worksheets("Employer Database").Sort
        .SetRange Range("A12:BD30")
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Range("B12").Select
    
    Application.ScreenUpdating = True
End Sub

until i realised that the list of items is going to be longer that the current range but I don't know how big it might get.

Is there an easy way to amend the code to identify that last row with something in column A and then select the range from A12 to BD (whatever the last row is).

I've had a go with a few things I have found on the internet but don't really know what I am doing.

Thanks in advance for any help

 

[JackDanIce]

Try:

Sub Macro1()

    Dim LR As Long
    
    Application.ScreenUpdating = False
    
    With Sheets("Employer Database")
        LR = .Range("A" & .Rows.Count).End(xlUp).Row
        If LR < 13 Then LR = 13
        .Range("A12:BD" & LR).Sort key1:=.Range("B12"), order1:=xlDescending, Header:=xlGuess
    End With
            
    Application.ScreenUpdating = True
    
End Sub

 

[DrH100]

Thanks JackDanIce that works brilliantly and is much neater than mine

 

[JackDanIce]

You're welcome.