Finding full path name in edit links

[UDcc123]

This question came up when we were in powerpoint, but it applies to excel too:

When we go to Edit Links, and look at the file name for external links, the entire path doesn't show up anywhere (the files are buried under mounds of subfolders). It says the file we are linked to doesn't exist anymore, so we need to go to the linked folder to see what happened, but the full path isn't displayed:

ex: \xyz123456\data\...\filename.xls

How can we find out what's in the ...

Again, this is more for powerpoint than excel, so we can just do a find/search option.

Thanks!

 

[BrianB]

To begin with, I am no Powerpoint expert - but hopefully you may be able to develop the following a bit more ....

First off, Powerpoint does not have the record macro capabilities of Excel - which makes life more difficult. Secondly, when dealing with links, the methods have to be different because Powerpoint does not have a LinkSources property. Here is something I cobbled together that seems to work. How would we write details to a slide ? :-

'===================================================
'- *POWERPOINT* CODE TO CHECK LINKS
'===================================================
Dim MySlide As Slide
Dim MyShape As Object
Dim MyLink As String
Dim LinkOK As String
'-----------------------------------------------
Sub test()
    For Each MySlide In ActivePresentation.Slides
        For Each MyShape In MySlide.Shapes
            If MyShape.Type = msoLinkedOLEObject Then
                MyLink = MyShape.LinkFormat.SourceFullName
                MyCheck = Dir(MyLink)
                LinkOK = IIf(MyCheck = "", "GONE", "OK")
                MsgBox (MyLink & vbCr & LinkOK)
            End If
        Next
    Next
End Sub
'======================================================

For the record, this is an Excel version :-

'=================================================================================
'- *EXCEL* LIST ACTIVE WORKBOOK LINKS (makes new sheet) 
'- AND CHECK IF FILES STILL EXIST
'- Brian Baulsom December 2007
'=================================================================================
Sub test()
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim MyLinks As Variant  ' array for links
    Dim MyLink As String
    Dim ToRow As Long
    Dim MyCheck As String
    '------------------------------------------------------------------------
    '- add a worksheet for results
    Set wb = ActiveWorkbook
    wb.Worksheets.Add before:=wb.Worksheets(1)
    Set ws = ActiveSheet
    '-------------------------------------------------------------------------
    '- get the links
    MyLinks = ActiveWorkbook.LinkSources(xlExcelLinks)
    If IsEmpty(MyLinks) Then
        MsgBox ("No links")
    Else
        '---------------------------------------------------------------------
        '- loop to check links
        For ToRow = 1 To UBound(MyLinks)
            MyLink = MyLinks(ToRow)
            ws.Cells(ToRow, 1).Value = MyLink
            MyCheck = Dir(MyLink)
            ws.Cells(ToRow, 2).Value = IIf(MyCheck = "", "GONE", "OK")
        Next
        '---------------------------------------------------------------------
    End If
End Sub
'============================================================================

 

[bobbiejo1104]

Just wanted to say thanks for this code. After 9 years, it's still helpful. I appreciate it!

 

[BrianB]

Wow, I am still alive too!
"Thanks for the Memory ................."