Find multiple values in different rows

[FilleFrella44]

Hello,

I am having issues retreving data based on the attatched image. I want to be able to see every value for "Serier" per "Ver". See example Output 1 and output 2 what I am aiming to recreate. Not sure if Excel has the capabilities to retrive information in that way since the cell next to it is empty.

The real-life use case is that I have ver-numbers in a column connected to some other data, and I want to know what all of the series numbers are per that ver-number in another document. Unfortunately cells are blank next to it, and I am unable to retrive the data in any way I know of. Further complications is that I would prefere output-2, but I am unsure how I would be able to move cells around using formulas. Perhaps this is solvable with a macro?

Somnething like this (not VBA code, but the functionallity)?
If (cell = ver, or if cell = blank after ver)
Retrive Serier-value
Go to next ver

 

[Legacy 143009]

Pase to cell A2:

=IFERROR(INDEX($D$1:$D$13,SMALL(IF($D$1:$D$13>0,ROW($D$1:$D$13)),ROWS($D$1:$D1))),"")

Paste to cell B2:

=TEXTJOIN(", ",1,OFFSET(INDEX($E$2:$E$13,MATCH($A2,$D$2:$D$13,0)),0,0,IFERROR(MATCH($A3,$D$2:$D$13,0),COUNTA($E$2:$E$13)+1)-MATCH($A2,$D$2:$D$13,0),1))

 

[FilleFrella44]

Thank you, I'll try this and get back to you how it turned out!

 

[FilleFrella44]

Hello, it worked exactly as intended! Had to mix and match a bit to get it to use the areas I had in my other document but the logic was exactly what I was looking for.

 

[Legacy 143009]

Glad to hear it did worked. Thanks for the feedback

 

[Legacy 143009]

Oh yes you are right. These INDEXes should start from second row:

=IFERROR(INDEX($D$2:$D$13,SMALL(IF($D$2:$D$13>0,ROW($D$1:$D$12)),ROWS($D$1:$D1))),"")

Or

=IFERROR(INDEX($D$1:$D$13,SMALL(IF($D$1:$D$13>0,ROW($D$1:$D$13)),ROWS($D$1:$D2))),"")