Find dates

[Gusher]

In col a I have month end dates. In col B I have percentages. I need a function that will return the date of the lowest number in Col B.

Many Thanks

 

[awoohaw]

What if the lowest number in column B appears multiple times (on different dates)? What date do you want to have returned?

 

[Joe4]

See this example:

Formula in cell D2:

=INDEX(A2:A7,MATCH(MIN(B2:B7),B2:B7,0))

 

[awoohaw]

You don't have your version on your button, so there are a few options. Please update your profile accordingly.

Try these:

Book1
	A	B	C	D	E	F	G
1				First Lowest Non 365	Last Lowest Non 365	First Lowest 365	Last Lowest 365
2	2024-01-31	56%		2024-02-29	2024-09-30	2024-02-29	2024-09-30
3	2024-02-29	50%
4	2024-03-31	54%
5	2024-04-30	52%
6	2024-05-31	54%
7	2024-06-30	56%
8	2024-07-31	57%
9	2024-08-31	51%
10	2024-09-30	50%
11	2024-10-31	59%
12	2024-11-30	60%
13	2024-12-31	51%
14
15
16
Sheet2

Cell Formulas
Range	Formula
D2	D2	=INDEX(A2:A13,MATCH(MIN($B$2:$B$13),B2:B13,0))
E2	E2	=INDEX(A2:A13,MAX(((MIN($B$2:$B$13)=B2:B13)*(ROW(B2:B13)-1))))
F2	F2	=XLOOKUP(MIN(B2:B13),B2:B13,A2:A13,"not found",0,1)
G2	G2	=XLOOKUP(MIN(B2:B13),B2:B13,A2:A13,"not found",0,-1)
A3:A13	A3	=EOMONTH(A2,1)

 

[Gusher]

See this example:

View attachment 113201

Formula in cell D2:

=INDEX(A2:A7,MATCH(MIN(B2:B7),B2:B7,0))

Many thanks, all good. Mark

 

[Joe4]

You are welcome.
Glad we were able to help!