Find Computer Serial Number

[Fire_Chief]

What code can I use to find the serial number of my computer?

Below is what I have been using but I have discovered it is not the serial number
that is on the computer.
I now do not know what the number I do get represents.

Public Function GetSerialNumber() As String
Dim objs As Object
Dim Obj As Object
Dim WMI As Object
Dim sAns As String
Set WMI = GetObject("WinMgmts:")
Set objs = WMI.InstancesOf("Win32_BaseBoard")
For Each Obj In objs
sAns = sAns & Obj.SerialNumber
If sAns < objs.Count Then sAns = sAns & ","
Next

SerialNumber = sAns

End Function

 

[jasonb75]

Which serial number are you referring to? There is no guarantee that the serial number on the back of the case is located in the bios.
What does

Debug.Print Shell("WMIC BIOS GET SERIALNUMBER")

give you?

 

[Logit]

.
This will give you the HD serial number :

Option Explicit


Function HdNum() As String
    Dim fsObj As Object
    Dim drv As Object
    Set fsObj = CreateObject("Scripting.FileSystemObject")
    Set drv = fsObj.Drives("C")
    HdNum = Hex(drv.serialnumber)
End Function

Then in a cell enter : =HdNum()




The Mother Board Serial Number :

Option Explicit


Public Function MBSerialNumber() As String


'RETRIEVES SERIAL NUMBER OF MOTHERBOARD
'IF THERE IS MORE THAN ONE MOTHERBOARD, THE SERIAL
'NUMBERS WILL BE DELIMITED BY COMMAS


'YOU MUST HAVE WMI INSTALLED AND A REFERENCE TO
'Microsoft WMI Scripting Library IS REQUIRED


Dim objs As Object


Dim obj As Object
Dim WMI As Object
Dim sAns As String




Set WMI = GetObject("WinMgmts:")
Set objs = WMI.InstancesOf("Win32_BaseBoard")
For Each obj In objs
  sAns = sAns & obj.SerialNumber
 If sAns < objs.Count Then sAns = sAns & ","
Next
MBSerialNumber = sAns
End Function

Enter in a cell : =MBSerialNumber()






To get the CPU ID :

Private Function CpuId() As String
Dim computer As String
Dim wmi As Variant
Dim processors As Variant
Dim cpu As Variant
Dim cpu_ids As String


    computer = "."
    Set wmi = GetObject("winmgmts:" & _
        "{impersonationLevel=impersonate}!\\" & _
        computer & "\root\cimv2")
    Set processors = wmi.ExecQuery("Select * from " & _
        "Win32_Processor")


    For Each cpu In processors
        cpu_ids = cpu_ids & ", " & cpu.ProcessorId
    Next cpu
    If Len(cpu_ids) > 0 Then cpu_ids = Mid$(cpu_ids, 3)


    CpuId = cpu_ids
End Function

In a cell enter : =CpuId()

 

[Fire_Chief]

Thank all. This was helpful

 

[Logit]

You are welcome.