Find closest values

[jokei]

Hi,
I'm new to macros and can't find a good starting point for my problem.

I want to loop through a row in a table looking for the 3 closest numbers (column D) to a value in a given cell (N5) and set the corresponding row to "yes" in column B.
So if the 3 closest values is found in D3, D6 and D7 I want B3, B6 and B7 to say "Yes" and then filter my list accordingley.

Help appreciated.

Regard Jokei

 

[mikerickson]

You could use this.

Sub test()
    Dim targetValue As Double
    Dim dblDist1 As Double, dblDist2 As Double, dblDist3 As Double
    Dim dblWorking As Double
    Dim oneCell As Range, rngData As Range
    Dim strFormula As String
    targetValue = Val(CStr(Range("N5").Value))
    dblDist1 = 9E+99
    dblDist2 = dblDist1
    dblDist3 = dblDist1
    With Range("D:D")
        Set rngData = Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
    End With
    For Each oneCell In rngData
        dblWorking = Abs(Val(CStr(oneCell.Value)) - targetValue)
        
        If dblWorking < dblDist1 Then
            dblDist3 = dblDist2
            dblDist2 = dblDist1
            dblDist1 = dblWorking
        ElseIf dblWorking < dblDist2 Then
            dblDist3 = dblDist2
            dblDist2 = dblWorking
        ElseIf dblWorking < dblDist3 Then
            dblDist3 = dblWorking
        End If
    Next oneCell
    strFormula = "=IF(ABS(RC[1]-(" & targetValue & "))<=" & dblDist3 & ",""yes"","""")"
    With rngData.Offset(0, -1)
        .FormulaR1C1 = strFormula
        .Value = .Value
    End With

End Sub

 

[jokei]

Hi,
This was almost perfect.
Only issue I get is that I'm not able to use a different column as a range, cause it only works with offseting -1 column for the "Yes".
I want to edit it so I can run it on other columns also but need to offset more then one column for the result.
And also it should not clear the target column cause I might have "yes" from other results which I want to keep.

And one last thing, how do I make it skip the two first rows which is headings?

Thanks!

 

[mikerickson]

Adjust the offset to suit your needs.

With rngData.Offset(0, -1)

 

[jokei]

That is not working, I tried offset(0,-5) and it gives #value or just blank. It seems to only work with -1. It returns #value if I adjust with -1 and blank if I adjust with more.
Also how do I avoid formula blanking if there is already "yes"?

 

[mikerickson]

What column is your data in, and what column do you want to have the result in?

 

[mikerickson]

When adjusting the Offset, the formula needs to be adjiusted as well

strFormula = "=IF(ABS(RC[1]-(" & targetValue & "))<=" & dblDist3 & ",""yes"","""")"
    With rngData.Offset(0, -1)
        .FormulaR1C1 = strFormula
        .Value = .Value
    End With

 

[jokei]

Data in F and writing to E which works well. But I wanted to apply same code to K and still write to E without overwriting if there was a "yes" from the code run on F. I clear everything with a separate code which I managed to do myself.

 

[jokei]

I guess I need some sort of if before the formula for writing the results?

 

[mikerickson]

Perhaps this will work for you

Sub test()
    Dim rngDestination As Range
    Dim dblTargetValue As Double
    Dim rngData As Range
    Dim lngDataCount As Long
    Dim dblAbsTarget As Double
    Dim strFormula As String
    Dim arrResult() As String
    Dim oneCell As Range, oneCol As Variant
    Dim i As Long
    
    Set rngDestination = Range("C1")
    dblTargetValue = Val(CStr(Range("N5").Value))
    
    ReDim arrResult(1 To 1)
    
    For Each oneCol In Array(Range("D:D"), Range("K:K"))
        With oneCol.EntireColumn
            Set rngData = Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
            strFormula = .Cells(1, 1).Address(False, False, xlR1C1, True, rngDestination)
        End With
        
        lngDataCount = rngData.Rows.Count
        With rngDestination.Resize(lngDataCount, 1)
            .FormulaR1C1 = "=ABS(" & strFormula & "-" & dblTargetValue & ")"
            dblAbsTarget = WorksheetFunction.Small(.Cells, 3)
        End With
        
        If UBound(arrResult, 1) < lngDataCount Then ReDim Preserve arrResult(1 To lngDataCount)

        For i = 1 To lngDataCount
            If rngDestination.Cells(i, 1) <= dblAbsTarget Then
                arrResult(i) = Trim(arrResult(i) & " Yes") & Split(rngData.Address(True, False), "$")(0)
            End If
        Next i
    Next oneCol
    rngDestination.Offset(0, -1).Resize(UBound(arrResult), 1).Value = Application.Transpose(arrResult)
End Sub