Find and replace using PPT VBA

[raghavcacs]

Hi,

The question regarding Find and replace in PPT VBA. I am trying to find the file path of the linked objects in a PPT and replace part of it with the latest files. Can you please help me how to do it?

Find = March month file name
Replace = April month file name

This ppt has more than 200 links from the same file. Hence going by the usual "Edit links" is laborious and time consuming.

Any help on this would be highly appreciable.

 

[Domenic]

The first macro replaces part of the filename for all linked objects in the active slide. The second one replaces part of the filename for all linked objects in all slides in the active presentation. For these two examples, it simply replaces "March" with "April", so you may need to amend it accordingly. Note that the code must be placed in a regular module within your PowerPoint presentation file.

For the active slide...

Sub UpdateLinkedObjectsInActiveSlide()


    Dim oSlide As Slide
    Dim oShape As Shape
    
    Set oSlide = Application.ActiveWindow.View.Slide
    
    For Each oShape In oSlide.Shapes
        If oShape.Type = msoLinkedOLEObject Then
            oShape.LinkFormat.SourceFullName = Replace(oShape.LinkFormat.SourceFullName, "March", "April", 1, 1, vbTextCompare)
        End If
    Next oShape
    
End Sub

For all slides in the active presentation...

Sub UpdateLinkedObjectsInActivePresentation()


    Dim oSlide As Slide
    Dim oShape As Shape
    
    For Each oSlide In ActivePresentation.Slides
        For Each oShape In oSlide.Shapes
            If oShape.Type = msoLinkedOLEObject Then
                oShape.LinkFormat.SourceFullName = Replace(oShape.LinkFormat.SourceFullName, "March", "April", 1, 1, vbTextCompare)
            End If
        Next oShape
    Next oSlide


End Sub

Hope this helps!

 

[raghavcacs]

Thanks Domenic for your quick and invaluable help. I will try and keep you posted.