Find a set of characters embedded in a word and change the entire words format

[KYLE05]

I am new to VBA and have not been able to find a solution to a current problem I am having. The title may be confusing but this is what I want to do.

I want to search the entire document for these sets of characters
"ZJIGS" and "ZMOLD".

Then change their color without changing the color of other words in the cell which I have been able to do. The issue is they are always found imbedded in a word in this format
"ZJIGS-XXXX###-####-#" or "ZMOLD-XXXX###-####-#"

I want to change the entire string of characters colors shown above. My previous efforts have only been able to change the color of the ZJIGS or ZMOLD portion.
I am using excell 2010

Thank you

 

[NeonRedSharpie]

Sub colorWords()

For Each Cell In ActiveWorkbook.ActiveSheet.UsedRange
    If InStr(1, Cell.value, "ZMOLD") >= 0 Or InStr(1, Cell.value, "ZJIGS") > 0 Then
        Cell.Font.color = vbBlue
    End If
    
Next
End Sub

 

[Rick Rothstein]

Does this macro do what you want...

Sub ZJIGSandZMOLD()
  Dim ZJIG As Long, ZMOLD As Long, Cell As Range
  Application.ScreenUpdating = False
  For Each Cell In ActiveSheet.UsedRange
    ZJIG = InStr(1, Cell.Value, "ZJIG", vbTextCompare)
    ZMOLD = InStr(1, Cell.Value, "ZMOLD", vbTextCompare)
    Do While ZJIG + ZMOLD > 0
      If ZJIG Then
        Cell.Characters(ZJIG, 21).Font.ColorIndex = 3
        ZJIG = InStr(ZJIG + 1, Cell.Value, "ZJIG", vbTextCompare)
      ElseIf ZMOLD Then
        Cell.Characters(ZMOLD, 21).Font.ColorIndex = 3
        ZMOLD = InStr(ZMOLD + 1, Cell.Value, "ZMOLD", vbTextCompare)
      End If
    Loop
  Next
  Application.ScreenUpdating = True
End Sub

 

[KYLE05]

This works perfect Rick. Thank you for the help.