filter unique value and transpose the 3rd column base on unique values

[ExcelNewbie2020]

Sirs,

would it be possible to filter the unique values from column A and B then transpose column C based on the unique values?.. please see the expected result..thank you

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1								EXPECTED RESULT
2	123	DOG	12				123	DOG	12	13	14	15	16	17	18
3	123	DOG	13				456	CAT	32	33	34	35	36	37
4	123	DOG	14
5	123	DOG	15
6	123	DOG	16
7	123	DOG	17
8	123	DOG	18
9	456	CAT	32
10	456	CAT	33
11	456	CAT	34
12	456	CAT	35
13	456	CAT	36
14	456	CAT	37
15
Sheet1

 

[JamesCanale]

MrExcelPlayground22.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1								EXPECTED RESULT
2	123	DOG	12				123	DOG	12	13	14	15	16	17	18
3	123	DOG	13				456	CAT	32	33	34	35	36	37
4	123	DOG	14
5	123	DOG	15				123	DOG	12	13	14	15	16	17	18
6	123	DOG	16				456	CAT	32	33	34	35	36	37
7	123	DOG	17
8	123	DOG	18
9	456	CAT	32
10	456	CAT	33
11	456	CAT	34
12	456	CAT	35
13	456	CAT	36
14	456	CAT	37
Sheet24

Cell Formulas
Range	Formula
G5:H6	G5	=UNIQUE(A2:B14)
I5:O5	I5	=TRANSPOSE(FILTER(C2:C14,(A2:A14=G5)*(B2:B14=H5)))
I6:N6	I6	=TRANSPOSE(FILTER(C2:C14,(A2:A14=G6)*(B2:B14=H6)))
Dynamic array formulas.

 

[ExcelNewbie2020]

MrExcelPlayground22.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1								EXPECTED RESULT
2	123	DOG	12				123	DOG	12	13	14	15	16	17	18
3	123	DOG	13				456	CAT	32	33	34	35	36	37
4	123	DOG	14
5	123	DOG	15				123	DOG	12	13	14	15	16	17	18
6	123	DOG	16				456	CAT	32	33	34	35	36	37
7	123	DOG	17
8	123	DOG	18
9	456	CAT	32
10	456	CAT	33
11	456	CAT	34
12	456	CAT	35
13	456	CAT	36
14	456	CAT	37
Sheet24

Cell Formulas
Range	Formula
G5:H6	G5	=UNIQUE(A2:B14)
I5:O5	I5	=TRANSPOSE(FILTER(C2:C14,(A2:A14=G5)*(B2:B14=H5)))
I6:N6	I6	=TRANSPOSE(FILTER(C2:C14,(A2:A14=G6)*(B2:B14=H6)))
Dynamic array formulas.

thanks, would it be possible in a single spill array formula?

 

[ExcelToDAX]

How about:

=HSTACK(UNIQUE(A2:B14),LET(ConcatColumn,LET(ColumnOne,A2:A14,ColumnTwo,B2:B14,ColumnThree,C2:C14,FirstTwoColumnsConcat,ColumnOne&ColumnTwo,CHOOSE({1,2},FirstTwoColumnsConcat,ColumnThree)),IFNA(DROP(TEXTSPLIT(CONCAT(BYROW(UNIQUE(INDEX(ConcatColumn,,1)),LAMBDA(val,TEXTJOIN(",",TRUE,FILTER(INDEX(ConcatColumn,,2),INDEX(ConcatColumn,,1)=val))))&"-"),",","-"),-1),"")))

 

[Fluff]

Another option

=LET(u,UNIQUE(A2:B14),IFNA(DROP(REDUCE("", SEQUENCE(ROWS(u)),LAMBDA(x,y,LET(a,INDEX(u,y,1),b,INDEX(u,y,2),VSTACK(x,HSTACK(a,b,TOROW(FILTER(C2:C14,(A2:A14=a)*(B2:B14=b)))))))),1),""))