FILLUP

[lrobbo314]

FILLUP fills a column with the value of a next cell is propagated to the null-valued cells below in the columns specified.

Also uses other LAMBDAs `FILLUP` and `REVTABLE` listed below.

FILLUP
	K	L	M	N	O	P	Q	R
1	FILLUP w/ error			FILLUP w/ zero			FILLUP w/ blank
2
3	#N/A	3		0	3			3
4	#N/A	3		0	3			3
5	#N/A	3		0	3			3
6	#N/A	3		0	3			3
7	#N/A	3		0	3			3
8	#N/A	3		0	3			3
9	3	3		3	3		3	3
10	#N/A	2		0	2			2
11	#N/A	2		0	2			2
12	#N/A	2		0	2			2
13	2	2		2	2		2	2
14	#N/A	1		0	1			1
15	#N/A	1		0	1			1
16	#N/A	1		0	1			1
17	#N/A	1		0	1			1
18	1	1		1	1		1	1
19
20
21	#N/A	C		0	C			C
22	#N/A	C		0	C			C
23	#N/A	C		0	C			C
24	#N/A	C		0	C			C
25	#N/A	C		0	C			C
26	#N/A	C		0	C			C
27	C	C		C	C		C	C
28	#N/A	B		0	B			B
29	#N/A	B		0	B			B
30	#N/A	B		0	B			B
31	B	B		B	B		B	B
32	#N/A	A		0	A			A
33	#N/A	A		0	A			A
34	#N/A	A		0	A			A
35	#N/A	A		0	A			A
36	A	A		A	A		A	A
Sheet3

Cell Formulas
Range	Formula
L3:L18,R21:R36,O21:O36,L21:L36,R3:R18,O3:O18	L3	=FILLUP(K3:K18)
Dynamic array formulas.

FILLUP

=LAMBDA(range,
    REVTABLE(FILLDOWN(REVTABLE(range)))
)

FILLDOWN

=LAMBDA(range,
    LET(
        r,IF((range=0)+(range="")+ISERROR(range),NA(),range),
        SCAN(0,r,LAMBDA(s,c,IF(ISERROR(c),s,c)))
    )
)

REVTABLE

=LAMBDA(table,
    LET(
        d,table,
        r,ROWS(d),
        INDEX(d,SEQUENCE(r,,r,-1),SEQUENCE(,COLUMNS(d)))
    )
)