fill a range with numbers - vba

[lezawang]

Hi
The code below is going to fill a range with random number but all the cells will get the same number. What I want, is to fill cells of that range with different random number. So I am thinking to put that line of code in a loop but how can I loop when user might enter any different range? How you would do that please. Thank you very much.

Sub cells_fill()
    Dim x as integer
    Dim y As Integer
    Dim n As Integer
    Dim m As Integer
    x = InputBox("row1")
    y = InputBox("col1")
    n = InputBox("row2")
    m = InputBox("col2")
    Range(Cells(x, y), Cells(n, m)).Value = WorksheetFunction.RandBetween(1, 100)
End Sub

 

[Michael M]

Try

Sub MM1()
Dim x As Integer, y As Integer
Dim n As Integer, m As Integer, cell As Range
x = InputBox("row1")
y = InputBox("col1")
n = InputBox("row2")
m = InputBox("col2")
For Each cell In Range(Cells(x, y), Cells(n, m))
    cell.Value = WorksheetFunction.RandBetween(1, 100)
Next cell
End Sub

 

[lezawang]

Thank you very much. Never thought of for-each. So happy to know it. thank you again.

 

[mikerickson]

Or perhaps one dialog box and no loop.

Dim RangeToFill As Range

On Error Resume Next
Set RangeToFill = Application.InputBox("Select a range to fill with the mouse", Type:=8)
On Error Goto 0

If RangeToFill Is Nothing then Exit Sub: Rem cancel pressed

With RangeToFill
    .Formula = "=RANDBETWEEN(1, 100)"
    .Value = .Value
End With

 

[lezawang]

Wow, thanks Mike. So interesting to learn different style. Thanks a lot again