Field Names

[dtaylor]

Hello All,
Is there a way, with vba, to list the field names of a table?

Thanks

Dan

 

[Russell Hauf]

There sure is. What version of Access are you using?

 

[dtaylor]

Hi Russell,
I am using 2000 but coding this project in DAO (just do not like how adodb creates tables and querys).

Would it be to much to ask to show both?

Def would be benificial to me since my users are on both.

Thanks

Dan
This message was edited by dtaylor on 2003-01-23 12:37

 

[Russell Hauf]

Here you go:


<pre>Option Compare Database
Option Explicit

Public Function PrintFieldsADO(strTableName As String)
Dim rst As ADODB.Recordset
Dim conn As Connection
Dim lngI As Long

Set rst = New ADODB.Recordset

rst.Open strTableName, CurrentProject.Connection, adOpenForwardOnly

With rst
For lngI = 0 To .Fields.Count - 1
Debug.Print .Fields(lngI).Name
Next lngI
.Close
End With

Set rst = Nothing

End Function

Public Function PrintFieldsDAO(strTableName As String)
Dim db As DAO.Database
Dim rst As DAO.Recordset
Dim lngI As Long

Set db = CurrentDb
Set rst = db.OpenRecordset(strTableName, dbOpenForwardOnly)

With rst
For lngI = 0 To .Fields.Count - 1
Debug.Print .Fields(lngI).Name
Next lngI
.Close
End With

Set rst = Nothing
End Function</pre>

HTH,

Russell