Extracting the date

[amwill]

i have a cell contents that look like this Sep 27th 2023 09:21:00. I use this formula DATEVALUE(MID(E2,5,2)&" "&LEFT(E2,3)&" "&MID(E2,10,4)) to get the date 9/27/2023. However if the days are lower than 10 it will give me a value error. Example: a cell contents with a date like this Sep 6th 2023 10:22:00 gives me the value error. is there a formula i can use that will capture the date no matter the amount of days?

 

[alansidman]

If you data is actual dates and not text, then all you will need to do is change the formatting. An alternative if it is Text is to bring it into the Power Query Editor and change the Text to Date/Time and then close and load back to native excel.

 

[amwill]

the data looks like this Sep 27th 2023 09:21:00 and i would prefer to just create a formula for someone so they don't have to do anything on their side.

 

[alansidman]

What the date looks like when posted here is immaterial because we cannot determine if it is text or numerical in your workbook. Post some samples using XL2BB as that will replicate what is in your workbook. No pictures!

 

[lrobbo314]

How about this?

EXCEL
	A	B
1	Sep 27th 2023 09:21:00	9/27/2023
2	Sep 6th 2023 10:22:00	9/6/2023
Sheet2

Cell Formulas
Range	Formula
B1:B2	B1	=LET(s,DROP(TEXTSPLIT(A1,," "),-1),m,MATCH(INDEX(s,1),{"Jan";"Feb";"Mar";"Apr";"May";"Jun";"Jul";"Aug";"Sep";"Oct";"Nov";"Dec"}),d,LEFT(INDEX(s,2),LEN(INDEX(s,2))-2),DATEVALUE(TEXTJOIN("/",,m,d,INDEX(s,3))))

 

[Dave Patton]

If you want an alternative that is not sensitive to Regional Settings, try the following
Custom format to your preference

Dates Time.xlsm
	A	B
1	Sep 27th 2023 09:21:00	27-Sep-2023 9:21:00
2	Sep 6th 2023 10:22:00	06-Sep-2023 10:22:00
3
4d

Cell Formulas
Range	Formula
B1:B2	B1	=DATE(TEXTBEFORE(TEXTAFTER(A1," ",2)," "),MONTH(1&LEFT(A1,3)),IFERROR(--MID(A1,5,2),--(MID(A1,5,1))))+TEXTAFTER(A1," ",3)

 

[Dave Patton]

or

Dates Time.xlsm
	A	B	C
1	Sep 27th 2023 09:21:00	27-Sep-2023 9:21:00	27-Sep-2023
2	Sep 6th 2023 10:22:00	06-Sep-2023 10:22:00	06-Sep-2023
3
4d

Cell Formulas
Range	Formula
B1:B2	B1	=DATE(TEXTBEFORE(TEXTAFTER(A1," ",2)," "),MONTH(1&LEFT(A1,3)),IFERROR(--MID(A1,5,2),--(MID(A1,5,1))))+TEXTAFTER(A1," ",3)
C1:C2	C1	=DATEVALUE(IFERROR(--MID(A1,5,2),MID(A1,5,1))&"-"&LEFT(A1,3)&"-"&TEXTBEFORE(TEXTAFTER(A1," ",2)," "))

 

[Tetra201]

Another approach -- just three function calls and one reference call; works in Excel 2010 and later:

=AGGREGATE(14,6,DATEVALUE(SUBSTITUTE(E2,{"st","nd","rd","th"},",")),1)

 

[Rick Rothstein]

Another approach -- just three function calls and one reference call; works in Excel 2010 and later:

=AGGREGATE(14,6,DATEVALUE(SUBSTITUTE(E2,{"st","nd","rd","th"},",")),1)

I think (but am not 100% sure) that converting text dates written like "Sep 12, 2023" into real dates is locale dependent. Your formula works in my US Locale but I don't think it is internationally universal. If it is, or if the OP's locale accepts it, then this formula would work in his XL365 version of Excel (it uses the same underlying principle that you did)...

=TOROW(INT(SUBSTITUTE(E2,{"st","nd","rd","th"},",")),3)