Extract specific string of text from cell

[CF64]

Hello,
I have a column of cells which contains strings of text separated by line breaks.
Is there a formula which I could use to find a string which starts with specific text and pull that string into the adjacent cell?
For example, in the table below "Massachusetts:..." appears in multiple cells with a different city after the ":"
Is there a formula to enter in the adjacent cell in Column B which searches for "Massachusetts:" and returns the entire string (i.e. Massachusetts: City) regardless of which line it appears on in each cell in Column A?
Thank you for your consideration of my question

Column A	Column B
Massachusetts: Boston Connecticut: Hartford California: Los Angeles	Massachusetts: Boston
Connecticut: New Haven California: San Diego Massachusetts: Boston	Massachusetts: Boston
Connecticut: Hartford California: Sacramento Massachusetts: Salem	Massachusetts: Salem

 

[Fluff]

How about

=FILTERXML("<k><m>"&SUBSTITUTE(A2,CHAR(10),"</m><m>")&"</m></k>","//m[starts-with(.,'Mass')]")

 

[CF64]

That works great - Thank you!!!!

 

[Fluff]

You're welcome & thansk for the feedback.

 

[CF64]

May I please ask 2 follow up questions?
Using the formula above, is there a way to just pull the text which is after the colon instead of he entire string?

If I have a cell in column A that has multiple "Massachusetts:...", how would I get both to appear in the cell in column B? Using the formula above I get a Spill error

Column A	Column B
Massachusetts: Boston Connecticut: Hartford California: Los Angeles	Massachusetts: Boston
Connecticut: New Haven Massachusetts: Salem Massachusetts: Boston	Massachusetts: Boston Massachusetts: Salem
Connecticut: Hartford California: Sacramento Massachusetts: Salem	Massachusetts: Salem

 

[Fluff]

For both values try.

=TEXTJOIN(CHAR(10),,FILTERXML("<k><m>"&SUBSTITUTE(A2,CHAR(10),"</m><m>")&"</m></k>","//m[starts-with(.,'Mass')]"))

 

[CF64]

For both values try.

=TEXTJOIN(CHAR(10),,FILTERXML("<k><m>"&SUBSTITUTE(A2,CHAR(10),"</m><m>")&"</m></k>","//m[starts-with(.,'Mass')]"))

Thank you!

 

[CF64]

If anyone knows a way to just pull the text which is after the colon instead of he entire string using the same formula would be greatly appreciated.

 

[Fluff]

Thought I'd posted that, but how about

=TEXTJOIN(CHAR(10),,FILTERXML("<k><m>"&SUBSTITUTE(SUBSTITUTE(A2,CHAR(10),"</m><m>"),":","</m><m>")&"</m></k>","//m[starts-with(.,'Mass')]/following::m[1]"))

 

[gyagos]

content removed

Sorry about that