Export Sheets as csv

[howard]

I have several sheet and have written code to export these to directory C:\data


I would like to mend the code to only export that sheets that has data in cell A1


Your assistance in this regard is most appreciated

 Sub ExportSheetsToCSV()
Application.DisplayAlerts = False
    Dim xWs As Worksheet
    Dim xcsvFile As String
    For Each xWs In Application.ActiveWorkbook.Worksheets
        xWs.Copy
        xcsvFile = "C:\data" & "\" & xWs.Name & ".csv"
        Application.ActiveWorkbook.SaveAs Filename:=xcsvFile, _
        FileFormat:=xlCSV, CreateBackup:=False
        Application.ActiveWorkbook.Saved = True
        Application.ActiveWorkbook.Close
    Next
    Close_Book
    Application.DisplayAlerts = True
    
End Sub

 

[JackDanIce]

Try:

Sub ExportSheetsToCSV()
 
    Dim xWs As Worksheet
    Const xcsvFile As String = "C:\data\@Name.csv"
     
    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With
    
    For Each xWs In ActiveWorkbook.Worksheets
        With xWs
            If Len(.Cells(1, 1).Value) > 0 Then
                .Copy
                ActiveWorkbook.SaveAs FileName:=Replace(xcsvFile, "@Name", .Name), FileFormat:=xlCSV, CreateBackup:=False
                With ActiveWorkbook
                    .Saved = True
                    .ActiveWorkbook.Close False
                End With
            End If
        End With
    Next xWs
    Close_Book
    
    With Application
        .DisplayAlerts = True
        .ScreenUpdating = True
    End With
    
End Sub

 

[howard]

Thanks for the help, much appreciated

 

[JackDanIce]

You're welcome