Export only one sheet as PDF - Save as prompt

[damnfabio]

Hi

Thanks for the help in advance on this matter.

I wanted to have a button on a landing page of a workbook to print a specific sheet named "leather letter" on the excel file.

So basically I would like that when someone clicks that button a prompt shows up with the "Save as" dialog so the user is able to select the location and the name of the file.

Can someone help me with this?

Thank you so much

 

[John_w]

Assign this macro to the button.

Public Sub Save_Sheet_As_PDF()

    Dim PDFfile As Variant
    
    PDFfile = Application.GetSaveAsFilename(InitialFileName:=ThisWorkbook.Path, _
                                            FileFilter:="PDF (*.pdf), *.pdf", _
                                            Title:="Save leather letter sheet as PDF")
    
    If PDFfile <> False Then
        ThisWorkbook.Worksheets("leather letter").ExportAsFixedFormat Type:=xlTypePDF, Filename:=PDFfile, _
        Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
    End If
        
End Sub

 

[damnfabio]

Assign this macro to the button.

Public Sub Save_Sheet_As_PDF()

    Dim PDFfile As Variant
   
    PDFfile = Application.GetSaveAsFilename(InitialFileName:=ThisWorkbook.Path, _
                                            FileFilter:="PDF (*.pdf), *.pdf", _
                                            Title:="Save leather letter sheet as PDF")
   
    If PDFfile <> False Then
        ThisWorkbook.Worksheets("leather letter").ExportAsFixedFormat Type:=xlTypePDF, Filename:=PDFfile, _
        Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
    End If
       
End Sub

Thank you so much!

This was the perfect solution!

Have a nice day