EXCEL/VBA QUESTION - how to open outlook and access one email content from inbox and further process using VBA

[shrivallabh amrute]

hello friends,

i wish to do following steps with vba code
1. open an outlook application and then go to subfolder of inbox , open one email with perticular subject and then open csv file attached to it

please help me with that rest thing i will manage as there is further process involved based on that cvs file

 

[ZVI]

Hi,
You may start with this code:

Sub Save_CSV_attachment()
 
  ' Outlook constant
  Const olFolderInbox = 6
  
  ' Settings, change to suit
  Const sDestFolder = "D:\Temp\"    ' Where to save CSV attachment
  Const sSubject = "My Subject"     ' Subject of the mail with attachment
  Const sSubFolderInInbox = "Test"  ' Name of Subfolder in Inbox
 
  ' Variables
  Dim OutlookApp As Object, oMail As Object, oAtt As Object
  Dim sFilter As String
 
  ' Check destinarion folder
  If Dir(sDestFolder, vbDirectory) = "" Then
    MsgBox "Destination folder not found: " & sDestFolder, vbExclamation, "Exit"
    Exit Sub
  End If
  
  ' Get/create outlook object
  On Error Resume Next
  Set OutlookApp = GetObject(, "Outlook.Application")
  If Err Then
    Set OutlookApp = CreateObject("Outlook.Application")
  End If
  On Error GoTo 0
 
  ' Build filter for restriction items by Subject
  sFilter = "[Subject] = '" & sSubject & "'"
 
  ' Main
  For Each oMail In OutlookApp.GetNamespace("MAPI").GetDefaultFolder(olFolderInbox).Folders(sSubFolderInInbox).Items.Restrict(sFilter)
    For Each oAtt In oMail.Attachments
      If LCase(oAtt.Filename) Like "*.csv" Then
        oAtt.SaveAsFile sDestFolder & oAtt.Filename
        MsgBox "Attachment is saved as " & sDestFolder & oAtt.Filename
        Exit For
      End If
    Next
  Next
  
  ' Release memory of the object variables
  Set oAtt = Nothing
  Set oMail = Nothing
  Set OutlookApp = Nothing
  
End Sub

 

[shrivallabh amrute]

thanks a lot . god bless you.