Excel VBA - Copy text from nested Word tables

[30136353]

Hi Guys,

Does anyone know a macro which would open a word document and copy all tables, included nested tables to an excel sheet? I have tried a couple different ones online but they don't seem to capture the nested tables. Another solution would be top copy ALL text from the word document to excel if that is possible?

Thanks.

 

[Rijnsent]

In order for other people to help you it is a good idea to share what you have done/tried so far. Share some files/screenshots/code, as this is not a coding service platform but merely volunteers wanting to help you with specific questions.
Cheers,
Koen

 

[Macropod]

The following macro will extract all tables, including nested ones, from all documents in the selected folder:

Sub GetTableData()
'Note: this code requires a reference to the Word object model. See under the VBE's Tools|References.
Application.ScreenUpdating = False
Dim wdApp As New Word.Application, wdDoc As Word.Document, wdTbl As Word.Table
Dim strFolder As String, strFile As String, WkBk As Workbook, WkSht As Worksheet, r As Long
strFolder = GetFolder: If strFolder = "" Then GoTo ErrExit
Set WkBk = ActiveWorkbook
'Disable any auto macros in the documents being processed
wdApp.WordBasic.DisableAutoMacros
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  Set wdDoc = wdApp.Documents.Open(Filename:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  Set WkSht = WkBk.Sheets.Add
  WkSht.Name = Split(strFile, ".doc")(0)
  With wdDoc
    For Each wdTbl In .Tables
      r = WkSht.Cells(WkSht.Rows.Count, 1).End(xlUp).Row
      If r > 1 Then r = r + 2
      wdTbl.Range.Copy
      WkSht.Paste Destination:=WkSht.Range("A" & r)
    Next
    .Close SaveChanges:=False
  End With
  strFile = Dir()
Wend
ErrExit:
wdApp.Quit
Set wdDoc = Nothing: Set wdApp = Nothing: Set WkSht = Nothing: Set WkBk = Nothing
Application.ScreenUpdating = True
End Sub
 
Function GetFolder() As String
    Dim oFolder As Object
    GetFolder = ""
    Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
    If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
    Set oFolder = Nothing
End Function

 

[30136353]

In order for other people to help you it is a good idea to share what you have done/tried so far. Share some files/screenshots/code, as this is not a coding service platform but merely volunteers wanting to help you with specific questions.
Cheers,
Koen

I wasn't asking for someone to write me a macro, I was asking if anyone had one at hand. I'd imagine its a macro which has been used many of times before... I searched over google multiple times and couldn't find anything, most likely because I didn't know what exactly to search for.

 

[Macropod]

The one I posted is more or less one I had to hand... See: Help with VBA to extract data from Word to Excel