Excel Userform VBA: Check Label Tag Property & Replace its Caption

[MrRajKumar]

Hi,

I am designing an userform. So basically i would like to get the following.

Design:
A simple form to data entry. I added a label on underneath of each control. If there is any error its caption shows errors in red color, so they can fix it.
So when the form initialize, I used a code to replace caption of every labels (error lablels) to a 'space'.

Question:
Looking for a function to check all labels 'tag' property. if the tag value is 'error' then change their caption to 'specific' value.

Eg:

ChangeLabelCaption(TagValue,NewCaption)
ChangeLableCapton("error"," ")

So I can call this function, rather to add a code for each label in the userform.

I hope my question is clear. If not, sorry, please feel free to ask.

 

[Domenic]

Try...

Private Sub ChangeLabelCaptions(ByVal TagValue As String, ByVal NewCaption As String)

    Dim ctrl As Control
    
    For Each ctrl In Me.Controls
        If TypeName(ctrl) = "Label" Then
            If LCase$(ctrl.Tag) = LCase$(TagValue) Then
                ctrl.Caption = NewCaption
            End If
        End If
    Next ctrl
    
End Sub

Then call the procedure as follows...

    ChangeLabelCaptions "Error", ""

Hope this helps!

 

[MrRajKumar]

Thank you Domenic for the help and sorry for the delay.

But I got error when run this procedure. It highlight the Me part.

How can I make this as global, then run on any userform in the project?

 

[Domenic]

Is this what you mean? If not, can you please specify the logic that's involved?

Sub test()

    ChangeLabelCaptions UserForm1, "Error", ""
  
    UserForm1.Show
  
End Sub

Sub ChangeLabelCaptions(ByVal uf As Object, ByVal TagValue As String, ByVal NewCaption As String)

    Dim ctrl As msforms.Control
  
    For Each ctrl In uf.Controls
        If TypeName(ctrl) = "Label" Then
            If LCase$(ctrl.Tag) = LCase$(TagValue) Then
                ctrl.Caption = NewCaption
            End If
        End If
    Next ctrl
  
End Sub