Excel Macro to update sheet values on another sheet where it find a match

[Alwinaz]

Hi

I am using this macro to update two rows on another sheet by finding the matching cell.

Sub findcode1()
     
    Dim wks As Worksheet
    Dim wks2 As Worksheet
    Dim myR As Range
    
    Set wks = Worksheets("Voorraad")
    Set wks2 = Worksheets("Koop")
    
    If Application.WorksheetFunction.CountIf(wks.Range("A:A"), wks2.Range("a6")) > 0 Then
        ask = wks.Range("A:A").Find(wks2.Range("a6"), wks.Range("A1")).Row
        wks.Range("c" & ask).Value = wks2.Range("g6").Value
       ' wks.Range("O" & ask).Value = wks2.Range("C11").Value
    'End If
    
    If Application.WorksheetFunction.CountIf(wks.Range("A:A"), wks2.Range("a7")) > 0 Then
        ask = wks.Range("A:A").Find(wks2.Range("a7"), wks.Range("A1")).Row
        wks.Range("c" & ask).Value = wks2.Range("g7").Value
       ' wks.Range("O" & ask).Value = wks2.Range("C11").Value
    End If
    End If
    


End sub

Is there a way to update wks will all the matches found in column A on wks2?

Kind regards
Alwina

 

[Fluff]

How about

Sub ReplaceVals()
   Dim Cl As Range
   Dim Ws1 As Worksheet, Ws2 As Worksheet
   
   Set Ws1 = Sheets("Voorraad")
   Set Ws2 = Sheets("Koop")
   With CreateObject("scripting.dictionary")
      For Each Cl In Ws2.Range("A6", Ws2.Range("A" & Rows.count).End(xlUp))
         .Item(Cl.Value) = Cl.Offset(, 6).Value
      Next Cl
      For Each Cl In Ws1.Range("A2", Ws1.Range("A" & Rows.count).End(xlUp))
         If .exists(Cl.Value) Then Cl.Offset(, 2).Value = .Item(Cl.Value)
      Next Cl
   End With
End Sub

 

[Alwinaz]

Thanks a million. Exactly what i needed.

 

[Fluff]

Glad to help & thanks for the feedback