Excel Macro - save all tabs (except specific ones) to single PDF file

[Ns2003]

Can you please help me with this? I would like to have a vba code that selects all tabs in the workbook, except for example "tab abc" and "tab def" and "tab ghi", then save to one single PDF.
Thanks in advance!

 

[John_w]

Welcome to MrExcel forums.

Try this code:

Public Sub Save_Sheets_As_PDF()

    Dim saveInFolder As String
    Dim replaceSelected As Boolean
    Dim ws As Worksheet
    Dim excludeSheets As String
    
    excludeSheets = "|abc|def|ghi|"        'The sheet names to exclude delimited by "|"
    
    saveInFolder = ThisWorkbook.Path
    If Right(saveInFolder, 1) <> "\" Then saveInFolder = saveInFolder & "\"
    
    With ThisWorkbook

        replaceSelected = True
        For Each ws In .Worksheets
            If InStr(excludeSheets, "|" & ws.Name & "|") = 0 Then
                ws.Select replaceSelected
                replaceSelected = False
            End If
        Next
            
        .ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=saveInFolder & "Sheets.pdf", _
            Quality:=xlQualityMinimum, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            
        .Worksheets(1).Select True
    
    End With
    
End Sub

 

[Ns2003]

Thanks John!

I will try this, just have one question.

What directory is the pdf file being sent to right? Is there any way that I can specify a specific path to save it to?


Thanks!

 

[John_w]

The PDF is saved in the same folder as the workbook. Change the saveInFolder string to a specific folder:

    saveInFolder = "C:\Path\to\folder"