Evaluate Time Stamps and Delete Rows with the oldest date per customer

[Plokimu77]

Hello Folks,

Is possible to have a macro evaluate two or more time stamps and delete the oldest one?

In addition, if only one order is found in column A (order for) then ignore and move to the set of orders.

Thank you as always.



This is my raw data

Order For	Time Stamp
Mike	9/2/2023 20:07
Mike	9/3/2023 20:12
John	8/27/2023 00:20
Mary	8/28/2023 09:21
Mary	8/29/2023 18:20
Kelly	8/30/2023 14:51
Melanie	7/25/2023 15:00
Melanie	8/26/2023 18:21
Melanie	8/26/2023 18:25

This would be the Final Result

Order For	Time Stamp
Mike	9/3/2023 20:12
John	8/27/2023 00:20
Mary	8/29/2023 18:20
Kelly	8/30/2023 14:51
Melanie	08/26/2023 18:25

 

[BigBeachBananas]

How about this?

WARNING: UNTESTED CODE - TRY ON A COPY OF YOUR WORKBOOK

Sub RemoveOldTimestamps()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim nameCol As Range
    Dim dateCol As Range
    Dim dict As Object
    Dim i As Long

    Set ws = ThisWorkbook.Worksheets("Sheet1") ' Replace "Sheet1" with your sheet name

    Set nameCol = ws.Range("A:A") 'Adjust columns
    Set dateCol = ws.Range("B:B") 'Adjust columns

    Set dict = CreateObject("Scripting.Dictionary")

    lastRow = ws.Cells(ws.Rows.Count, nameCol.Column).End(xlUp).Row

    For i = lastRow To 2 Step -1
        Dim name As String
        Dim timestamp As Date

        name = nameCol.Cells(i, 1).Value
        timestamp = dateCol.Cells(i, 1).Value
        If dict.Exists(name) Then
            If timestamp > dict(name) Then
                dict(name) = timestamp
            Else
                ws.Rows(i).Delete
            End If
        Else
            dict(name) = timestamp
        End If
    Next i
End Sub

 

[Plokimu77]

Awesome.

Thank you so much BigBeachBananas.

You are a lifesaver!

Special for a rookie like myself