Error: We Cannot Convert a value of Type Function to Type list

[SAMCRO2014]

I have been trying to create a function to calculate the number of working days (including holidays). I found instructions on how to create fnNetworkdays but I am getting the following error when I try to use it in a query:

Expression.Error: We cannot convert a value of type Function to type List.
Details:
Value=Function
Type=Type

I have no clue what it means. Here is my M coding for the function:

(StartDate as date, EndDate as date) as number =>
let
Source = List.Dates,
#"Invoked Function Source" =
if StartDate <= EndDate then
Source(StartDate,Duration.Days(EndDate-StartDate)+1, Duration.From(1))
else
Source(EndDate, Duration.Days(StartDate-EndDate)+1, Duration.From(1)),
#"Converted to Table" = Table.FromList(Source, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
#"Inserted Day of Week" = Table.AddColumn(#"Converted to Table", "Day of Week", each Date.DayOfWeek([Column1],Day.Monday), Int64.Type),
#"Filtered Rows" = Table.SelectRows(#"Inserted Day of Week", each ([Day of Week] <> 5 and [Day of Week] <> 6)),
Custom1 = if StartDate <= EndDate then Table.RowCount(#"Filtered Rows") else Table.RowCount(#"Filtered Rows")*(-1)
in
Custom1

Can anyone see where I am going wrong? This is the instructions I followed: https://www.powerquery.training/networkdays/

 

[bobby_smith]

I've had this problem before and it was because you were using a table instead of a list.
Click on the query column heading and select drill down.

 

[SAMCRO2014]

I need the information to stay in table format unfortunately

 

[peter789]

Shouldn't the line

#"Converted to Table" = Table.FromList(Source, Splitter.SplitByNothing(), null, null, ExtraValues.Error),

Actually be:
#"Converted to Table" = Table.FromList(#"Invoked Function Source", Splitter.SplitByNothing(), null, null, ExtraValues.Error),

 

[SAMCRO2014]

I will give it a try!

 

[arcrox]

I will give it a try!

Did you happen to identify a fix for this issue? I have the exact same problem and nothing I've tried has worked.

 

[SAMCRO2014]

Did you happen to identify a fix for this issue? I have the exact same problem and nothing I've tried has worked.

Nope. Cannot figure it out!!

 

[sandy666]

maybe try this

// fnGetParameter
(ParameterName as text) =>
    let
        ParamSource = Excel.CurrentWorkbook(){[Name="Parameters"]}[Content],
        ParamRow = Table.SelectRows(ParamSource, each ([Parameter]=ParameterName)),
            Value=
            if Table.IsEmpty(ParamRow)=true
                        then null
                        else Record.Field(ParamRow{0},"Value")
    in
        Value

// Calendar
let
    startdate = Number.From(fnGetParameter("StartDate")),
    enddate = Number.From(fnGetParameter("EndDate")),

    Source = {startdate..enddate},
    ToTable = Table.FromList(Source, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    Type = Table.TransformColumnTypes(ToTable,{{"Column1", type date}}),
    Rename = Table.RenameColumns(Type,{{"Column1", "Date"}}),
    Year = Table.AddColumn(Rename, "Year", each Date.Year([Date]), Int64.Type),
    Month = Table.AddColumn(Year, "Month", each Date.Month([Date]), Int64.Type),
    Day = Table.AddColumn(Month, "Day", each Date.Day([Date]), Int64.Type),
    Quarter = Table.AddColumn(Day, "Quarter", each Date.QuarterOfYear([Date]), Int64.Type),
    WeekOfYear = Table.AddColumn(Quarter, "Week of Year", each Date.WeekOfYear([Date]), Int64.Type),
    WeekOfMonth = Table.AddColumn(WeekOfYear, "Week of Month", each Date.WeekOfMonth([Date]), Int64.Type),
    MonthName = Table.AddColumn(WeekOfMonth, "Month Name", each Date.MonthName([Date]), type text),
    DayName = Table.AddColumn(MonthName, "Day Name", each Date.DayOfWeekName([Date]), type text)
in
    DayName

Parameter	Value		Date	Year	Month	Day	Quarter	Week of Year	Week of Month	Month Name	Day Name
StartDate	10/02/2020		10/02/2020	2020	2	10	1	7	3	February	Monday
EndDate	29/02/2020		11/02/2020	2020	2	11	1	7	3	February	Tuesday
			12/02/2020	2020	2	12	1	7	3	February	Wednesday
			13/02/2020	2020	2	13	1	7	3	February	Thursday
			14/02/2020	2020	2	14	1	7	3	February	Friday
			15/02/2020	2020	2	15	1	7	3	February	Saturday
			16/02/2020	2020	2	16	1	7	3	February	Sunday
			17/02/2020	2020	2	17	1	8	4	February	Monday
			18/02/2020	2020	2	18	1	8	4	February	Tuesday
			19/02/2020	2020	2	19	1	8	4	February	Wednesday
			20/02/2020	2020	2	20	1	8	4	February	Thursday
			21/02/2020	2020	2	21	1	8	4	February	Friday
			22/02/2020	2020	2	22	1	8	4	February	Saturday
			23/02/2020	2020	2	23	1	8	4	February	Sunday
			24/02/2020	2020	2	24	1	9	5	February	Monday
			25/02/2020	2020	2	25	1	9	5	February	Tuesday
			26/02/2020	2020	2	26	1	9	5	February	Wednesday
			27/02/2020	2020	2	27	1	9	5	February	Thursday
			28/02/2020	2020	2	28	1	9	5	February	Friday
			29/02/2020	2020	2	29	1	9	5	February	Saturday

 

[Cubelife]

I found this forum by following the directions on NetWorkDays - Power Query Training like the OP did. I also ran into the EXACT same error message. Fortunately, someone in the comment section of the original training provided their code which worked for me! Here's the code:

(StartDate as date, EndDate as date) as number =>
let
Source =
(if StartDate <= EndDate then
List.Dates(StartDate,
Duration.Days(EndDate-StartDate),
Duration.From(1))
else
List.Dates(EndDate,
Duration.Days(StartDate-EndDate),
Duration.From(1))
),
#"Converted to Table" = Table.FromList(Source, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
#"Inserted Day of Week" = Table.AddColumn(#"Converted to Table", "Day of Week", each Date.DayOfWeek([Column1], Day.Monday), Int64.Type),
#"Filtered Rows" = Table.SelectRows(#"Inserted Day of Week", each ([Day of Week] <> 5 and [Day of Week] <> 6)),
Custom1 = if StartDate <= EndDate then Table.RowCount(#"Filtered Rows") else Table.RowCount(#"Filtered Rows") * (-1)
in
Custom1